reserve i, x, I for set,
  A, M for ManySortedSet of I,
  f for Function,
  F for ManySortedFunction of I;
reserve P, R for MSSetOp of M,
  E, T for Element of bool M;
reserve S for 1-sorted;
reserve MS for many-sorted over S;

theorem
  MSFixPoints id A = A
proof
  now
    let i be object such that
A1: i in I;
    thus (MSFixPoints id A).i = A.i
    proof
      thus (MSFixPoints id A).i c= A.i
      proof
        let x be object;
        assume x in (MSFixPoints id A).i;
        then consider f being Function such that
A2:     f = (id A).i and
A3:     x in dom f and
        f.x = x by A1,Def12;
        f is Function of A.i, A.i by A1,A2,PBOOLE:def 15;
        hence thesis by A3,FUNCT_2:52;
      end;
      reconsider f = (id A).i as Function of A.i, A.i by A1,PBOOLE:def 15;
      let x be object such that
A4:   x in A.i;
A5:   x in dom f by A4,FUNCT_2:52;
      f = id (A.i) by A1,MSUALG_3:def 1;
      then f.x = x by A4,FUNCT_1:18;
      hence thesis by A1,A5,Def12;
    end;
  end;
  hence thesis;
end;
