
theorem Th29:
  for A being set holds A is Subset of REAL? & not REAL in A iff A
  is Subset of R^1 & NAT /\ A = {}
proof
  let A be set;
  thus A is Subset of REAL? & not REAL in A implies A is Subset of R^1 & NAT
  /\ A = {}
  proof
    assume that
A1: A is Subset of REAL? and
A2: not REAL in A;
    A c= the carrier of REAL? by A1;
    then
A3: A c= (REAL \ NAT) \/ {REAL} by Def8;
    A c= REAL
    proof
      let x be object;
      assume
A4:   x in A;
      then x in REAL \ NAT or x in {REAL} by A3,XBOOLE_0:def 3;
      hence thesis by A2,A4,TARSKI:def 1;
    end;
    hence A is Subset of R^1 by TOPMETR:17;
    thus NAT /\ A = {}
    proof
      set x = the Element of NAT /\ A;
      assume
A5:   NAT /\ A <> {};
      then
A6:   x in NAT by XBOOLE_0:def 4;
A7:   x in A by A5,XBOOLE_0:def 4;
      per cases by A3,A7,XBOOLE_0:def 3;
      suppose
        x in REAL \ NAT;
        hence contradiction by A6,XBOOLE_0:def 5;
      end;
      suppose
        x in {REAL};
        then x = REAL by TARSKI:def 1;
        then REAL in REAL by A6,NUMBERS:19;
        hence contradiction;
      end;
    end;
  end;
  assume that
A8: A is Subset of R^1 and
A9: NAT /\ A = {};
A10: A c= REAL \ NAT
  proof
    let x be object;
    assume
A11: x in A;
    then not x in NAT by A9,XBOOLE_0:def 4;
    hence thesis by A8,A11,TOPMETR:17,XBOOLE_0:def 5;
  end;
  REAL \ NAT c= (REAL \ NAT) \/ {REAL} by XBOOLE_1:7;
  then A c= (REAL \ NAT) \/ {REAL} by A10;
  hence A is Subset of REAL? by Def8;
  thus not REAL in A
  proof
    assume REAL in A;
    then REAL in REAL by A8,TOPMETR:17;
    hence contradiction;
  end;
end;
