reserve x, y, X for set;
reserve E for non empty set;
reserve e for Element of E;
reserve u, u1, v, v1, v2, w, w9, w1, w2 for Element of E^omega;
reserve F for Subset of E^omega;
reserve i, k, l for Nat;
reserve TS for non empty transition-system over F;
reserve S, T for Subset of TS;
reserve SA for non empty semiautomaton over F;
reserve A for non empty automaton over F;
reserve p, q for Element of A;
reserve TS for non empty transition-system over Lex(E) \/ {<%>E};

theorem Th29:
  w^v-succ_of (X, TS) = v-succ_of (w-succ_of (X, TS), TS)
proof
A1: now
    let x be object;
    assume
A2: x in v-succ_of (w-succ_of (X, TS), TS);
    then reconsider r = x as Element of TS;
    consider p being Element of TS such that
A3: p in w-succ_of (X, TS) and
A4: p, v ==>* r, TS by A2,REWRITE3:103;
    consider q being Element of TS such that
A5: q in X and
A6: q, w ==>* p, TS by A3,REWRITE3:103;
    q, w^v ==>* r, TS by A4,A6,REWRITE3:99;
    hence x in w^v-succ_of (X, TS) by A5,REWRITE3:103;
  end;
  now
    let x be object;
    assume
A7: x in w^v-succ_of (X, TS);
    then reconsider r = x as Element of TS;
    consider q being Element of TS such that
A8: q in X and
A9: q, w^v ==>* r, TS by A7,REWRITE3:103;
    consider p being Element of TS such that
A10: q, w ==>* p, TS and
A11: p, v ==>* r, TS by A9,Th28;
    p in w-succ_of (X, TS) by A8,A10,REWRITE3:103;
    hence x in v-succ_of (w-succ_of (X, TS), TS) by A11,REWRITE3:103;
  end;
  hence thesis by A1,TARSKI:2;
end;
