reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th29:
  proj1.:(Cl RightComp f) = proj1.:(L~f)
proof
  set g = Rotate(f,N-min L~f);
A1: L~f = L~g by REVROT_1:33;
  N-min L~f in rng f by SPRECT_2:39;
  then
A2: g/.1 = N-min L~g by A1,FINSEQ_6:92;
  thus proj1.:(Cl RightComp f) c= proj1.:(L~f)
  proof
A3: Cl RightComp f = (RightComp f) \/ L~f by Th21;
    let a be object;
    assume a in proj1.:(Cl RightComp f);
    then consider x being object such that
A4: x in the carrier of TOP-REAL 2 and
A5: x in Cl RightComp f and
A6: a = proj1.x by FUNCT_2:64;
    per cases by A5,A3,XBOOLE_0:def 3;
    suppose
A7:   x in RightComp f;
      reconsider x as Point of TOP-REAL 2 by A4;
      set b = |[x`1,N-bound L~f + 1]|;
      b`2 = N-bound L~f + 1 & N-bound L~f + 1 > N-bound L~f + 0 by XREAL_1:6;
      then b in LeftComp g by A1,A2,JORDAN2C:113;
      then b in LeftComp f by REVROT_1:36;
      then LSeg(x,b) meets L~f by A7,Th27;
      then consider c being object such that
A8:   c in LSeg(x,b) and
A9:   c in L~f by XBOOLE_0:3;
      reconsider c as Point of TOP-REAL 2 by A8;
A10:  b`1 = x`1;
      proj1.c = c`1 by PSCOMP_1:def 5
        .= x`1 by A8,A10,GOBOARD7:5
        .= a by A6,PSCOMP_1:def 5;
      hence thesis by A9,FUNCT_2:35;
    end;
    suppose
      x in L~f;
      hence thesis by A6,FUNCT_2:35;
    end;
  end;
  L~f = (Cl RightComp f) \ RightComp f by Th19;
  hence thesis by RELAT_1:123,XBOOLE_1:36;
end;
