 reserve a,x for Real;
 reserve n for Element of NAT;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,h,f1,f2 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem
 A c= Z & f=exp_R/(cos*exp_R)^2
 & Z c= dom (tan*exp_R) & Z = dom f & f|A is continuous
 implies integral(f,A)=(tan*exp_R).(upper_bound A)-(tan*exp_R).(lower_bound A)
proof
  assume
A1:A c= Z & f=exp_R/(cos*exp_R)^2
   & Z c= dom (tan*exp_R) & Z = dom f & f|A is continuous;then
A2:f is_integrable_on A & f|A is bounded by INTEGRA5:10,11;
A3:tan*exp_R is_differentiable_on Z by A1,FDIFF_8:12;
   Z = dom exp_R /\ (dom ((cos*exp_R)^2) \ ((cos*exp_R)^2)"{0})
     by A1,RFUNCT_1:def 1;then
   Z c= dom ((cos*exp_R)^2) \ ((cos*exp_R)^2)"{0} by XBOOLE_1:18; then
A4:Z c= dom (((cos*exp_R)^2)^) by RFUNCT_1:def 2;
   dom (((cos*exp_R)^2)^) c= dom ((cos*exp_R)^2) by RFUNCT_1:1;then
Z c= dom ((cos*exp_R)^2) by A4;
then A5:Z c= dom (cos*exp_R) by VALUED_1:11;
A6:for x st x in Z holds f.x=exp_R.x/(cos.(exp_R.x))^2
   proof
   let x;
   assume
A7:x in Z;
   then
(exp_R/(cos*exp_R)^2).x =exp_R.x/((cos*exp_R)^2).x by A1,RFUNCT_1:def 1
  .=exp_R.x/((cos*exp_R).x)^2 by VALUED_1:11
  .=exp_R.x/(cos.(exp_R.x))^2 by A5,A7,FUNCT_1:12;
   hence thesis by A1;
   end;
A8:for x being Element of REAL st x in dom ((tan*exp_R)`|Z)
   holds ((tan*exp_R)`|Z).x=f.x
   proof
   let x be Element of REAL;
   assume x in dom ((tan*exp_R)`|Z);then
A9:x in Z by A3,FDIFF_1:def 7;then
  ((tan*exp_R)`|Z).x=exp_R.x/(cos.(exp_R.x))^2 by A1,FDIFF_8:12
  .=f.x by A6,A9;
  hence thesis;
  end;
  dom ((tan*exp_R)`|Z)=dom f by A1,A3,FDIFF_1:def 7;
  then ((tan*exp_R)`|Z)= f by A8,PARTFUN1:5;
  hence thesis by A1,A2,FDIFF_8:12,INTEGRA5:13;
end;
