reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;
reserve G for Go-board;

theorem Th29:
  for p1,p2,p3,p4,p be Point of TOP-REAL 2 st (p1`1 = p2`1 & p3`1
= p4`1 or p1`2 = p2`2 & p3`2 = p4`2) & LSeg(p1,p2) /\ LSeg(p3,p4) = {p} holds p
  =p1 or p=p2 or p=p3
proof
  let p1,p2,p3,p4,p be Point of TOP-REAL 2 such that
A1: p1`1 = p2`1 & p3`1 = p4`1 or p1`2 = p2`2 & p3`2 = p4`2 and
A2: LSeg(p1,p2) /\ LSeg(p3,p4) = {p};
A3: p in LSeg(p1,p2) /\ LSeg(p3,p4) by A2,TARSKI:def 1;
  then p in LSeg(p3,p4) by XBOOLE_0:def 4;
  then LSeg(p3,p) \/ LSeg(p,p4) = LSeg(p3,p4) by TOPREAL1:5;
  then
A4: LSeg(p3,p) c= LSeg(p3,p4) by XBOOLE_1:7;
A5: LSeg(p1,p2) meets LSeg(p3,p4) by A3;
A6: now
    assume p1`2 = p2`2 & p3`2 = p4`2;
    then LSeg(p1,p2) is horizontal & LSeg(p3,p4) is horizontal by SPPOL_1:15;
    hence p2`2 = p3`2 by A5,SPRECT_3:9;
  end;
A7: now
    assume p1`1 = p2`1 & p3`1 = p4`1;
    then LSeg(p1,p2) is vertical & LSeg(p3,p4) is vertical by SPPOL_1:16;
    hence p2`1 = p3`1 by A5,Th24;
  end;
A8: p3 in LSeg(p3,p4) by RLTOPSP1:68;
A9: p2 in LSeg(p1,p2) by RLTOPSP1:68;
A10: p1 in LSeg(p1,p2) by RLTOPSP1:68;
  now
A11: p in LSeg(p1,p2) by A3,XBOOLE_0:def 4;
    assume that
A12: p<>p1 and
A13: p<>p2 and
A14: p<>p3;
A15: now
      assume p3 in LSeg(p1,p2);
      then p3 in LSeg(p1,p2) /\ LSeg(p3,p4) by A8,XBOOLE_0:def 4;
      hence contradiction by A2,A14,TARSKI:def 1;
    end;
    now
      per cases by A1,A7,A6,A12,A13,A11,A15,Th28;
      suppose
        p1 in LSeg(p3,p);
        then p1 in LSeg(p1,p2) /\ LSeg(p3,p4) by A4,A10,XBOOLE_0:def 4;
        hence contradiction by A2,A12,TARSKI:def 1;
      end;
      suppose
        p2 in LSeg(p3,p);
        then p2 in LSeg(p1,p2) /\ LSeg(p3,p4) by A4,A9,XBOOLE_0:def 4;
        hence contradiction by A2,A13,TARSKI:def 1;
      end;
    end;
    hence contradiction;
  end;
  hence thesis;
end;
