reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;

theorem
  X (-) (B\/C) = (X (-) B)/\(X (-) C)
proof
  thus X (-) (B\/C) c= (X (-) B)/\(X (-) C)
  proof
    let x be object;
    assume x in X (-) (B\/C);
    then consider y being Point of T such that
A1: x = y and
A2: (B\/C)+y c= X;
A3: (B+y)\/(C+y) c= X by A2,Th27;
    then C+y c= X by XBOOLE_1:11;
    then
A4: x in {y1 where y1 is Point of T:C+y1 c= X} by A1;
    B+y c= X by A3,XBOOLE_1:11;
    then x in {y1 where y1 is Point of T:B+y1 c= X} by A1;
    hence thesis by A4,XBOOLE_0:def 4;
  end;
  let x be object;
  assume
A5: x in (X (-) B)/\(X (-) C);
  then x in X (-) B by XBOOLE_0:def 4;
  then consider y being Point of T such that
A6: x = y and
A7: B+y c= X;
  x in X (-) C by A5,XBOOLE_0:def 4;
  then ex y2 being Point of T st x = y2 & C+y2 c= X;
  then (B+y)\/(C+y) c= X by A6,A7,XBOOLE_1:8;
  then (B\/C)+y c= X by Th27;
  hence thesis by A6;
end;
