reserve i,j,m,n,k for Nat,
  x,y for set,
  K for Field,
  a,L for Element of K;
reserve V1,V2 for finite-dimensional VectSp of K,
  W1,W2 for Subspace of V1,
  U1 ,U2 for Subspace of V2,
  b1 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,
  bw1 for OrdBasis of W1,
  bw2 for OrdBasis of W2,
  Bu1 for FinSequence of U1,
  Bu2 for FinSequence of U2;

theorem Th29:
  for V1 be finite-dimensional VectSp of K for F be nilpotent
linear-transformation of V1,V1 ex J be non-empty FinSequence_of_Jordan_block of
  0.K,K, b1 be OrdBasis of V1 st AutMt(F,b1,b1) = block_diagonal(J,0.K)
proof
  defpred P[Nat] means for V1 be finite-dimensional VectSp of K for F be
  nilpotent linear-transformation of V1,V1 st deg F=$1 holds ex J be
FinSequence_of_Jordan_block of 0.K,K, b1 be OrdBasis of V1 st AutMt(F,b1,b1) =
  block_diagonal(J,0.K) & for i st i in dom J holds (Len J).i <> 0;
  let V1 be finite-dimensional VectSp of K;
  let F be nilpotent linear-transformation of V1,V1;
A1: for n st P[n] holds P[n+1]
  proof
    let n such that
A2: P[n];
    let V1 be finite-dimensional VectSp of K;
    set n1=n+1;
    let F be nilpotent linear-transformation of V1,V1 such that
A3: deg F=n1;
    set BAS = the Basis of V1;
A4: BAS is linearly-independent by VECTSP_7:def 3;
A5: Lin(BAS) = the ModuleStr of V1 by VECTSP_7:def 3;
    set IM=im F|^1;
    reconsider FI=F|IM as linear-transformation of IM,IM by VECTSP11:32;
    reconsider FI as nilpotent linear-transformation of IM,IM by Th17;
    deg FI+1=n1 by A3,Th18,NAT_1:11;
    then consider
    J be FinSequence_of_Jordan_block of 0.K,K, b1 be OrdBasis of IM
    such that
A6: AutMt(FI,b1,b1) = block_diagonal(J,0.K) and
A7: for i st i in dom J holds (Len J).i <> 0 by A2;
A8: len b1 = len AutMt(FI,b1,b1) by MATRIX_0:def 2
      .= Sum Len J by A6,MATRIXJ1:def 5;
    then
A9: dom b1= Seg Sum Len J by FINSEQ_1:def 3;
    set L=len J;
    set LJ=Len J;
    set S=Sum LJ;
    defpred Q[Nat,Nat] means $2 in dom LJ & $2 <= $1 & Sum(LJ| ($2-'1)) <= $1-'
    $2;
    defpred R[object,object] means
    for i,k st i=$1 & k=$2 holds Q[i,k] & i-'k <= Sum
    (LJ|k) & for n st Q[i,n] holds n<=k;
A10: for x being object st x in Seg(S+L)
   ex y being object st y in NAT & R[x,y]
    proof
      let x be object such that
A11:  x in Seg (S+L);
      reconsider i=x as Nat by A11;
      L<>0
      proof
        assume
A12:    L=0;
        then LJ=<*>NAT;
        hence thesis by A11,A12,RVSUM_1:72;
      end;
      then
A13:  1<=L by NAT_1:14;
      1-'1=0 by XREAL_1:232;
      then
A14:  Sum(LJ| (1-'1))=0 by RVSUM_1:72;
      defpred q[Nat] means $1 in dom LJ & $1 <= i & Sum(LJ| ($1-'1)) <= i-'$1;
A15:  for k st q[k] holds k <= L
      proof
        let k;
        assume q[k];
        then k<=len LJ by FINSEQ_3:25;
        hence thesis by CARD_1:def 7;
      end;
      len LJ=L by CARD_1:def 7;
      then
A16:  0<=i-'1 & 1 in dom LJ by A13,FINSEQ_3:25;
      1<=i by A11,FINSEQ_1:1;
      then
A17:  ex k st q[k] by A14,A16;
      consider k such that
A18:  q[k] and
A19:  for n st q[n] holds n <= k from NAT_1:sch 6(A15,A17);
A20:  i-'k <= Sum (LJ|k)
      proof
        assume
A21:    i-'k > Sum (LJ|k);
        then i-'k >= Sum (LJ|k)+1 by NAT_1:13;
        then
A22:    i-'k-1>=Sum (LJ|k)+1-1 by XREAL_1:9;
A23:    i-'k=i-k by A18,XREAL_1:233;
A24:    k+1<=len LJ
        proof
          assume k+1>len LJ;
          then
A25:      k>=len LJ by NAT_1:13;
          then i-k>S by A21,A23,FINSEQ_1:58;
          then
A26:      i-k+k>S+k by XREAL_1:6;
          len LJ=L by CARD_1:def 7;
          then S+k>=S+L by A25,XREAL_1:6;
          then i> S+L by A26,XXREAL_0:2;
          hence thesis by A11,FINSEQ_1:1;
        end;
        1<=k+1 by NAT_1:14;
        then
A27:    k+1 in dom LJ by A24,FINSEQ_3:25;
        i-'k>=1 by A21,NAT_1:14;
        then
A28:    i-k+k >=1+k by A23,XREAL_1:6;
        then i-'(k+1)=i-(k+1) by XREAL_1:233;
        then Sum(LJ| (k+1-'1)) <= i-'(k+1) by A22,A23,NAT_D:34;
        then k+1<=k by A19,A28,A27;
        hence thesis by NAT_1:13;
      end;
      take k;
      thus k in NAT by ORDINAL1:def 12;
      let i9,k9 be Nat;
      assume i9=x & k9=k;
      hence thesis by A18,A19,A20;
    end;
    consider r be Function of Seg (S+L),NAT such that
A29: for x being object st x in Seg (S+L) holds R[x,r.x]
        from FUNCT_2:sch 1(A10);
    defpred P[object,object] means
     for i,k st i=$1 & k=r.i holds (i -' k = Sum (LJ| (
k-'1)) implies (F.$2 = b1.(i -' k+1) & i-'k+1 in dom b1)) & (i -' k <> Sum (LJ|
(k-'1)) implies ($2 = b1.(i -' k) & i-'k in dom b1 & min(LJ,i-'k)=k & ((i-'k <
Sum (LJ|k) implies F.$2 = b1.(i -' k+1) & i -' k+1 in dom b1) & (i-'k = Sum (LJ
    |k) implies F.$2 = 0.V1))));
A30: dom r=Seg (S+L) by FUNCT_2:def 1;
A31: FI=Mx2Tran(AutMt(FI,b1,b1),b1,b1) by MATRLIN2:34;
A32: for x being object st x in Seg (S+L)
ex y being object st y in the carrier of V1 & P[x,y]
    proof
      let x be object such that
A33:  x in Seg (S+L);
      reconsider i=x as Nat by A33;
      r.i=r/.i by A30,A33,PARTFUN1:def 6;
      then reconsider k=r.i as Element of NAT;
A34:  i-'k <= Sum (LJ|k) by A29,A33;
A35:  Q[i,k] by A29,A33;
      then
A36:  LJ.k =len (J.k) by MATRIXJ1:def 3;
      k<=len LJ by A35,FINSEQ_3:25;
      then
A37:  Sum (LJ|k) <= Sum (LJ| (len LJ)) by POLYNOM3:18;
      1<=k by A35,FINSEQ_3:25;
      then
A38:  k-'1=k-1 by XREAL_1:233;
      then k=k-'1+1;
      then LJ|k=(LJ| (k-'1))^<*LJ.k*> by A35,FINSEQ_5:10;
      then
A39:  dom LJ=dom J & Sum (LJ|k)=Sum (LJ| (k-'1)) + len (J.k) by A36,
MATRIXJ1:def 3,RVSUM_1:74;
A40:  LJ| (len LJ) =LJ by FINSEQ_1:58;
      per cases;
      suppose
A41:    i -' k = Sum (LJ| (k-'1));
        b1/.(i-'k+1) in IM & b1/.(i-'k+1) is Element of V1 by VECTSP_4:10;
        then consider y be Element of V1 such that
A42:    (F|^1).y=b1/.(i-'k+1) by RANKNULL:13;
        take y;
        thus y in the carrier of V1;
        i-'k <> Sum (LJ|k) by A7,A35,A36,A39,A41;
        then i-'k < Sum (LJ|k) by A34,XXREAL_0:1;
        then i-'k+1 <=Sum(LJ|k) by NAT_1:13;
        then
A43:    1<= i-'k+1 & i-'k+1 <= S by A37,A40,NAT_1:11,XXREAL_0:2;
        then i-'k+1 in dom b1 by A9;
        then b1/.(i-'k+1) = b1.(i-'k+1) by PARTFUN1:def 6;
        hence thesis by A9,A41,A43,A42,VECTSP11:19;
      end;
      suppose
A44:    i -' k <> Sum (LJ| (k-'1));
        take y=b1/.(i-'k);
        y in IM;
        then y in V1 by VECTSP_4:9;
        hence y in the carrier of V1;
        i -' k>Sum (LJ| (k-'1)) by A35,A44,XXREAL_0:1;
        then
A45:    1<= i-'k by NAT_1:14;
        i-'k <= S by A34,A37,A40,XXREAL_0:2;
        then
A46:    i-'k in dom b1 by A9,A45;
        i-'k <= Sum (LJ|k) by A29,A33;
        then
A47:    min(LJ,i-'k)<=k by A9,A46,MATRIXJ1:def 1;
A48:    min(LJ,i-'k)=k
        proof
          assume min(LJ,i-'k)<>k;
          then min(LJ,i-'k)<k-'1+1 by A38,A47,XXREAL_0:1;
          then min(LJ,i-'k) <=k-'1 by NAT_1:13;
          then
A49:      Sum(LJ|min(LJ,i-'k)) <= Sum (LJ| (k-'1)) by POLYNOM3:18;
          i-'k <= Sum(LJ|min(LJ,i-'k)) by A9,A46,MATRIXJ1:def 1;
          then i-'k <= Sum (LJ| (k-'1)) by A49,XXREAL_0:2;
          hence thesis by A35,A44,XXREAL_0:1;
        end;
A50:    Len J|k=LJ|k by MATRIXJ1:17;
A51:    now
          assume
A52:      i-'k = Sum (LJ|k);
          F.(b1/.(i-'k)) = FI.(b1/.(i-'k)) by FUNCT_1:49
            .= 0.K*(b1/.(i-'k)) by A6,A31,A46,A48,A50,A52,Th24
            .= 0.IM by VECTSP_1:14
            .= 0.V1 by VECTSP_4:11;
          hence F.y = 0.V1;
        end;
A53:    now
          assume
A54:      i-'k < Sum (LJ|k);
          then i-'k+1<=Sum (LJ|k) by NAT_1:13;
          then
A55:      1<=i-'k+1 & i-'k+1<=S by A37,A40,NAT_1:11,XXREAL_0:2;
          then
A56:      i-'k+1 in dom b1 by A9;
          F.(b1/.(i-'k)) = FI.(b1/.(i-'k)) by FUNCT_1:49
            .= 0.K*(b1/.(i-'k))+(b1/.(i-'k+1)) by A6,A31,A46,A48,A50,A54,Th24
            .= 0.IM+(b1/.(i-'k+1)) by VECTSP_1:14
            .= b1/.(i-'k+1) by RLVECT_1:def 4
            .= b1.(i-'k+1) by A56,PARTFUN1:def 6;
          hence F.y = b1.(i -' k+1) & i -' k+1 in dom b1 by A9,A55;
        end;
        let i9,k9 be Nat;
        assume x=i9 & k9=r.i9;
        hence thesis by A44,A46,A48,A53,A51,PARTFUN1:def 6;
      end;
    end;
    consider B be Function of Seg (S+L),the carrier of V1 such that
A57: for x being object st x in Seg (S+L) holds P[x,B.x]
from FUNCT_2:sch 1(A32);
A58: rng B c= the carrier of V1 by RELAT_1:def 19;
A59: dom B=Seg (S+L) by FUNCT_2:def 1;
    then reconsider B as FinSequence by FINSEQ_1:def 2;
    reconsider B as FinSequence of V1 by A58,FINSEQ_1:def 4;
    reconsider RNG=rng B as Subset of V1 by FINSEQ_1:def 4;
    now
      rng b1 is Basis of IM by MATRLIN:def 2;
      then rng b1 is linearly-independent Subset of IM by VECTSP_7:def 3;
      then reconsider rngb1=rng b1 as linearly-independent Subset of V1 by
VECTSP_9:11;
      set RB={v1 where v1 is Vector of V1: ex i,k st i in Seg(L+S) & k=r.i &
      v1=B.i & i-'k <> Sum (LJ| (k-'1)) & i-'k = Sum (LJ|k)};
      set RA={v1 where v1 is Vector of V1: ex i,k st i in Seg(L+S) & k=r.i &
      v1=B.i & i-'k < Sum (LJ|k)};
A60:  RA c= the carrier of V1
      proof
        let x be object;
        assume x in RA;
        then ex v1 be Vector of V1 st x=v1 & ex i,k st i in Seg(L+S) & k=r.i
        & v1=B.i & i-'k < Sum (LJ|k);
        hence thesis;
      end;
      RB c= the carrier of V1
      proof
        let x be object;
        assume x in RB;
        then ex v1 be Vector of V1 st x=v1 & ex i,k st i in Seg(L+S) & k=r.i
        & v1=B.i & i-'k <> Sum (LJ| (k-'1)) & i-'k = Sum (LJ|k);
        hence thesis;
      end;
      then reconsider RA,RB as Subset of V1 by A60;
      let l be Linear_Combination of RNG such that
A61:  Sum l = 0.V1;
A62:  F|RA is one-to-one
      proof
        let x1,x2 be object such that
A63:    x1 in dom (F|RA) and
A64:    x2 in dom (F|RA) and
A65:    (F|RA).x1=(F|RA).x2;
A66:    (F|RA).x1=F.x1 & (F|RA).x2=F.x2 by A63,A64,FUNCT_1:47;
A67:    dom(F|RA)=dom F /\ RA by RELAT_1:61;
        then x1 in RA by A63,XBOOLE_0:def 4;
        then consider v1 be Vector of V1 such that
A68:    x1=v1 and
A69:    ex i1,k1 be Nat st i1 in Seg(L+S) & k1=r.i1 & v1=B.i1 & i1-'
        k1 < Sum (LJ|k1);
        consider i1,k1 be Nat such that
A70:    i1 in Seg(L+S) & k1=r.i1 and
A71:    v1=B.i1 and
A72:    i1-'k1 < Sum (LJ|k1) by A69;
        k1<=i1 by A29,A70;
        then
A73:    i1-'k1=i1-k1 by XREAL_1:233;
A74:    k1 in dom LJ by A29,A70;
        then 1<=k1 by FINSEQ_3:25;
        then
A75:    k1-'1=k1-1 by XREAL_1:233;
        then k1-'1+1<=len LJ by A74,FINSEQ_3:25;
        then
A76:    k1-'1 <=len LJ by NAT_1:13;
A77:    b1 is one-to-one by MATRLIN:def 2;
A78:    dom LJ=dom J by MATRIXJ1:def 3;
        then
A79:    k1-'1 in dom LJ implies LJ.(k1-'1)<>0 by A7;
        x2 in RA by A64,A67,XBOOLE_0:def 4;
        then consider v2 be Vector of V1 such that
A80:    x2 = v2 and
A81:    ex i2,k2 be Nat st i2 in Seg(L+S) & k2=r.i2 & v2=B.i2 & i2-'
        k2 < Sum (LJ|k2);
        consider i2,k2 be Nat such that
A82:    i2 in Seg(L+S) & k2=r.i2 and
A83:    v2=B.i2 and
A84:    i2-'k2 < Sum (LJ|k2) by A81;
A85:    k2<=i2 by A29,A82;
        then
A86:    i2-'k2=i2-k2 by XREAL_1:233;
A87:    k2 in dom LJ by A29,A82;
        then 1<=k2 by FINSEQ_3:25;
        then
A88:    k2-'1=k2-1 by XREAL_1:233;
        then k2-'1+1<=len LJ by A87,FINSEQ_3:25;
        then
A89:    k2-'1 <=len LJ by NAT_1:13;
A90:    k2-'1 in dom LJ implies LJ.(k2-'1)<>0 by A7,A78;
        per cases;
        suppose
A91:      i1-'k1=Sum (LJ| (k1-'1)) & i2-'k2=Sum (LJ| (k2-'1));
          then
A92:      F.v2=b1.(i2 -' k2+1) & i2 -' k2+1 in dom b1 by A57,A82,A83;
          F.v1=b1.(i1 -' k1+1) & i1 -' k1+1 in dom b1 by A57,A70,A71,A91;
          then i1-'k1+1=i2-'k2+1 by A65,A66,A68,A80,A77,A92;
          then k1-'1=k2-'1 by A76,A89,A79,A90,A91,MATRIXJ1:11;
          then i1-k1=i2-k1 by A85,A73,A75,A88,A91,XREAL_1:233;
          hence thesis by A68,A71,A80,A83;
        end;
        suppose
A93:      i1-'k1=Sum (LJ| (k1-'1)) & i2-'k2<>Sum (LJ| (k2-'1));
          then
A94:      min(LJ,i2-'k2)=k2 by A57,A82;
A95:      F.v1=b1.(i1-'k1+1) & i1-'k1+1 in dom b1 by A57,A70,A71,A93;
          F.v2=b1.(i2-'k2+1) & i2-'k2+1 in dom b1 by A57,A82,A83,A84,A93;
          then
A96:      i1-'k1+1=i2-'k2+1 by A65,A66,A68,A80,A77,A95;
          k1-'1 <>0
          proof
            assume k1-'1=0;
            then LJ| (k1-'1)=<*>REAL;
            hence thesis by A29,A82,A93,A96,RVSUM_1:72;
          end;
          then k1-'1 >=1 by NAT_1:14;
          then
A97:      k1-'1 in dom LJ by A76,FINSEQ_3:25;
          then LJ.(k1-'1)<>0 by A7,A78;
          hence thesis by A84,A93,A94,A96,A97,MATRIXJ1:6;
        end;
        suppose
A98:      i1-'k1<>Sum (LJ| (k1-'1)) & i2-'k2=Sum (LJ| (k2-'1));
          then
A99:      min(LJ,i1-'k1)=k1 by A57,A70;
A100:     F.v2=b1.(i2-'k2+1) & i2-'k2+1 in dom b1 by A57,A82,A83,A98;
          F.v1=b1.(i1-'k1+1) & i1-'k1+1 in dom b1 by A57,A70,A71,A72,A98;
          then
A101:     i1-'k1+1=i2-'k2+1 by A65,A66,A68,A80,A77,A100;
          k2-'1 <>0
          proof
            assume k2-'1=0;
            then i1-'k1 =0 by A98,A101,RVSUM_1:72;
            hence thesis by A29,A70,A98;
          end;
          then k2-'1 >=1 by NAT_1:14;
          then
A102:     k2-'1 in dom LJ by A89,FINSEQ_3:25;
          then LJ.(k2-'1)<>0 by A7,A78;
          hence thesis by A72,A98,A99,A101,A102,MATRIXJ1:6;
        end;
        suppose
A103:     i1-'k1<>Sum (LJ| (k1-'1)) & i2-'k2<>Sum (LJ| (k2-'1));
          then
A104:     min(LJ,i2-'k2)=k2 by A57,A82;
A105:     F.v2=b1.(i2-'k2+1) & i2-'k2+1 in dom b1 by A57,A82,A83,A84,A103;
          F.v1=b1.(i1-'k1+1) & i1-'k1+1 in dom b1 by A57,A70,A71,A72,A103;
          then i1-'k1+1=i2-'k2+1 by A65,A66,A68,A80,A77,A105;
          then i1 - k1 =i2-k1 by A57,A70,A73,A86,A103,A104;
          hence thesis by A68,A71,A80,A83;
        end;
      end;
A106: RB c= rngb1
      proof
        let x be object;
        assume x in RB;
        then consider v1 be Vector of V1 such that
A107:   x=v1 and
A108:   ex i,k st i in Seg(L+S) & k=r.i & v1=B.i & i-'k <> Sum (LJ| (
        k-'1)) & i-'k = Sum (LJ|k);
        consider i,k such that
A109:   i in Seg(L+S) & k=r.i & v1=B.i & i-'k <> Sum (LJ| (k-'1)) and
        i-'k = Sum (LJ|k) by A108;
        v1= b1.(i -' k) & i-'k in dom b1 by A57,A109;
        hence thesis by A107,FUNCT_1:def 3;
      end;
A110: Carrier l c= RB\/RA
      proof
        let x be object such that
A111:   x in Carrier l;
        reconsider v1=x as Vector of V1 by A111;
        Carrier l c= RNG by VECTSP_6:def 4;
        then consider i be object such that
A112:   i in dom B and
A113:   B.i=v1 by A111,FUNCT_1:def 3;
        reconsider i as Nat by A112;
        r.i=r/.i by A30,A59,A112,PARTFUN1:def 6;
        then reconsider k=r.i as Element of NAT;
A114:   i-'k <= Sum (LJ|k) by A29,A59,A112;
        per cases by A114,XXREAL_0:1;
        suppose
A115:     i-'k = Sum (LJ|k);
A116:     Q[i,k] by A29,A59,A112;
          then 1<=k by FINSEQ_3:25;
          then k-'1=k-1 by XREAL_1:233;
          then k-'1+1=k;
          then LJ|k=(LJ| (k-'1))^<*LJ.k*> by A116,FINSEQ_5:10;
          then dom LJ=dom J & i-'k = Sum (LJ| (k-'1))+LJ.k by A115,
MATRIXJ1:def 3,RVSUM_1:74;
          then i-'k <>Sum (LJ| (k-'1)) by A7,A116;
          then v1 in RB or v1 in RA by A59,A112,A113,A115;
          hence thesis by XBOOLE_0:def 3;
        end;
        suppose
          i-'k < Sum (LJ|k);
          then v1 in RB or v1 in RA by A59,A112,A113;
          hence thesis by XBOOLE_0:def 3;
        end;
      end;
      F.:RA c= rngb1
      proof
        let y be object;
        assume y in F.:RA;
        then consider x being object such that
        x in dom F and
A117:   x in RA and
A118:   y=F.x by FUNCT_1:def 6;
        consider v1 be Vector of V1 such that
A119:   x=v1 and
A120:   ex i,k st i in Seg(L+S) & k=r.i & v1=B.i&i-'k < Sum (LJ|k) by A117;
        consider i,k such that
A121:   i in Seg(L+S) & k=r.i & v1=B.i & i-'k < Sum (LJ|k) by A120;
        i-'k <> Sum (LJ| (k-'1)) or i-'k = Sum (LJ| (k-'1));
        then F.v1= b1.(i -' k+1) & i -' k+1 in dom b1 by A57,A121;
        hence thesis by A118,A119,FUNCT_1:def 3;
      end;
      then
A122: F.:RA is linearly-independent Subset of V1 by VECTSP_7:1;
      F.:RB c= {0.V1}
      proof
        let y be object;
        assume y in F.:RB;
        then consider x being object such that
        x in dom F and
A123:   x in RB and
A124:   y=F.x by FUNCT_1:def 6;
        consider v1 be Vector of V1 such that
A125:   x=v1 and
A126:   ex i,k st i in Seg(L+S) & k=r.i & v1=B.i & i-'k <> Sum (LJ| (
        k-'1)) & i-'k = Sum (LJ|k) by A123;
        F.v1= 0.V1 by A57,A126;
        hence thesis by A124,A125,TARSKI:def 1;
      end;
      then Carrier l c= RB by A61,A110,A62,A122,VECTSP11:44;
      then Carrier l c= rngb1 by A106;
      then l is Linear_Combination of rngb1 by VECTSP_6:def 4;
      hence Carrier l ={} by A61,VECTSP_7:def 1;
    end;
    then
A127: RNG is linearly-independent Subset of V1 by VECTSP_7:def 1;
    reconsider BAS,RNG as finite Subset of V1;
    consider C be finite Subset of V1 such that
    C c= BAS and
A128: card C = card BAS - card RNG and
A129: the ModuleStr of V1= Lin(RNG\/C) by A127,A5,VECTSP_9:19;
A130: (Omega).Lin(BAS) = (Omega).V1 by VECTSP_7:def 3;
    then
A131: dim V1 =dim Lin BAS by VECTSP_9:28;
    defpred W[Nat] means $1 <= card C implies ex f be FinSequence of V1 st f
is one-to-one & len f = card C & RNG misses rng f & RNG\/rng f is Basis of V1 &
    for i st i in dom f & i<= $1 holds F.(f.i)=0.V1;
A132: for n st W[n] holds W[n+1]
    proof
      let n such that
A133: W[n];
      set n1=n+1;
      assume
A134: n1<=card C;
      then consider f be FinSequence of V1 such that
A135: f is one-to-one and
A136: len f = card C and
A137: RNG misses rng f and
A138: RNG\/rng f is Basis of V1 and
A139: for i st i in dom f & i<= n holds F.(f.i)=0.V1 by A133,NAT_1:13;
      per cases;
      suppose
        F.(f.n1)=0.V1;
        then for i st i in dom f & i<=n1 holds F.(f.i)=0.V1 by A139,NAT_1:8;
        hence thesis by A135,A136,A137,A138;
      end;
      suppose
A140:   F.(f.n1)<>0.V1;
        reconsider Rf=RNG\/rng f as finite Subset of V1 by A138;
        reconsider rngB1=rng b1 as Basis of IM by MATRLIN:def 2;
        set fn=f/.n1;
        1<=n1 by NAT_1:14;
        then
A141:   n1 in dom f by A134,A136,FINSEQ_3:25;
        then
A142:   f/.n1=f.n1 by PARTFUN1:def 6;
A143:   rng b1 c= F.:RNG
        proof
A144:     dom F=[#]V1 by FUNCT_2:def 1;
          let y be object;
          assume y in rng b1;
          then consider x being object such that
A145:     x in dom b1 and
A146:     b1.x=y by FUNCT_1:def 3;
          reconsider x as Element of NAT by A145;
A147:     len LJ=L & x<=S by A8,A145,CARD_1:def 7,FINSEQ_3:25;
          set m=min(LJ,x);
A148:     x<= Sum(LJ|m) by A9,A145,MATRIXJ1:def 1;
A149:     m in dom LJ by A9,A145,MATRIXJ1:def 1;
          then m<=len LJ by FINSEQ_3:25;
          then m+x<=L+S by A147,XREAL_1:7;
          then
A150:     m+x-1<=L+S-1 by XREAL_1:9;
          set x1=x-'1;
A151:     1<=x by A145,FINSEQ_3:25;
          then
A152:     x1=x-1 by XREAL_1:233;
          1<=m by A149,FINSEQ_3:25;
          then 1+1<=m+x by A151,XREAL_1:7;
          then
A153:     2-1<=m+x-1 by XREAL_1:9;
          set mx=m+x1;
A154:     mx-'m=mx-m by NAT_1:11,XREAL_1:233;
          L+S-1<=L+S-0 by XREAL_1:10;
          then mx<=L+S by A152,A150,XXREAL_0:2;
          then
A155:     mx in Seg (S+L) by A152,A153;
          then r.mx=r/.mx by A30,PARTFUN1:def 6;
          then reconsider k=r.mx as Element of NAT;
A156:     B.mx in RNG by A59,A155,FUNCT_1:def 3;
A157:     Sum(LJ| (m-'1))< x1+1 by A9,A145,A152,MATRIXJ1:7;
          then m<=mx & Sum(LJ| (m-'1))<= mx-'m by A154,NAT_1:11,13;
          then
A158:     m<=k by A29,A149,A155;
A159:     m=k
          proof
            assume m<>k;
            then
A160:       m<k by A158,XXREAL_0:1;
            then reconsider k1=k-1 as Element of NAT by NAT_1:20;
A161:       k=k1+1;
            then m<=k1 by A160,NAT_1:13;
            then
A162:       Sum(LJ|m)<=Sum(LJ|k1) by POLYNOM3:18;
A163:       mx-'k<=mx-'m by A158,NAT_D:41;
            k-'1=k1 by A161,NAT_D:34;
            then Sum(LJ|k1) <=mx-'k by A29,A155;
            then Sum(LJ|m) <=mx-'k by A162,XXREAL_0:2;
            then Sum(LJ|m)<=x1 by A154,A163,XXREAL_0:2;
            hence thesis by A152,A157,A148,NAT_1:13;
          end;
A164:     mx-'m =Sum(LJ| (m-'1)) or mx-'m <>Sum(LJ| (m-'1));
          mx-'m<Sum(LJ|m) by A152,A154,A157,A148,NAT_1:13;
          then F.(B.mx)= b1.(mx-'m+1) by A57,A155,A159,A164;
          hence thesis by A146,A152,A154,A156,A144,FUNCT_1:def 6;
        end;
        F.(f/.n1) in im F & F|^1=F by RANKNULL:13,VECTSP11:19;
        then F.(f/.n1) in Lin(rngB1) by VECTSP_7:def 3;
        then consider L be Linear_Combination of rngB1 such that
A165:   F.(f/.n1) = Sum L by VECTSP_7:7;
        consider K be Linear_Combination of V1 such that
A166:   Carrier L=Carrier K and
A167:   Sum L=Sum K by VECTSP_9:8;
        Carrier L c= rngB1 by VECTSP_6:def 4;
        then consider M be Linear_Combination of RNG such that
A168:   F.(Sum M)=Sum K by A143,A166,VECTSP11:41,XBOOLE_1:1;
A169:   f.n1 in rng f by A141,FUNCT_1:def 3;
        then
A170:   fn in Rf by A142,XBOOLE_0:def 3;
A171:   not fn in RNG by A137,A142,A169,XBOOLE_0:3;
        not fn in RNG by A137,A142,A169,XBOOLE_0:3;
        then
A172:   RNG c= Rf\{fn} by XBOOLE_1:7,ZFMISC_1:34;
        Carrier M c= RNG & Carrier M=Carrier(-M) by VECTSP_6:38,def 4;
        then Carrier(-M) c= Rf\{fn} by A172;
        then reconsider M9=-M as Linear_Combination of Rf\{fn} by
VECTSP_6:def 4;
        set fnM=fn+Sum(M9);
A173:   fnM <> fn
        proof
          assume fnM=fn;
          then 0.V1 = fnM-fn by VECTSP_1:16
            .= Sum(M9)+(fn-fn) by RLVECT_1:def 3
            .= Sum(M9)+0.V1 by RLVECT_1:def 10
            .= Sum(M9) by RLVECT_1:def 4
            .= -Sum(M) by VECTSP_6:46;
          then 0.V1=Sum(M) by VECTSP_1:28;
          hence thesis by A140,A142,A165,A167,A168,RANKNULL:9;
        end;
        take ff=f+*(n1,fnM);
        set fnS=n1 .--> fnM;
A174:   Rf is linearly-independent by A138,VECTSP_7:def 3;
A175:   not fnM in Rf\{fn}
        proof
          card Rf <>0 by A169;
          then reconsider c1=card Rf-1 as Element of NAT by NAT_1:20;
          assume fnM in Rf\{fn};
          then
A176:     Rf\{fn}\/ {fnM} = Rf\{fn} by ZFMISC_1:40;
          c1+1=card Rf;
          then
A177:     card (Rf\{fn})= c1 by A170,STIRL2_1:55;
          card (Rf\{fn}\/ {fnM})=c1+1 by A174,A170,VECTSP11:40;
          hence thesis by A177,A176;
        end;
        not fnM in rng f
        proof
          assume fnM in rng f;
          then fnM in Rf by XBOOLE_0:def 3;
          hence thesis by A175,A173,ZFMISC_1:56;
        end;
        then
A178:   rng f misses {fnM} by ZFMISC_1:50;
        rng fnS={fnM} by FUNCOP_1:8;
        then f+*(fnS) is one-to-one by A135,A178,FUNCT_4:92;
        hence ff is one-to-one by A141,FUNCT_7:def 3;
A179:   dom ff=dom f by FUNCT_7:30;
        hence len ff=card C by A136,FINSEQ_3:29;
A180:   rng ff = (rng f)\{fn} \/{fnM} by A135,A141,A142,Lm1;
        thus RNG misses rng ff
        proof
          assume RNG meets rng ff;
          then consider x being object such that
A181:     x in RNG and
A182:     x in rng ff by XBOOLE_0:3;
          not x in (rng f)\{fn} by A137,A181,XBOOLE_0:3;
          then x in {fnM} by A180,A182,XBOOLE_0:def 3;
          then
A183:     x = fnM by TARSKI:def 1;
          not fnM in Rf by A175,A173,ZFMISC_1:56;
          hence thesis by A181,A183,XBOOLE_0:def 3;
        end;
A184:   Rf\{fn}\/{fnM} = (RNG\{fn})\/((rng f)\{fn})\/{fnM} by XBOOLE_1:42
          .= RNG\/((rng f)\{fn})\/{fnM} by A171,ZFMISC_1:57
          .= RNG\/ rng ff by A180,XBOOLE_1:4;
        then reconsider Rff=RNG\/ rng ff as finite Subset of V1;
        dim V1 = card Rf by A138,VECTSP_9:def 1
          .= card (RNG\/ rng ff) by A174,A170,A184,VECTSP11:40;
        then dim Lin(Rff)=dim V1 by A174,A170,A184,VECTSP11:40,VECTSP_9:26;
        then
A185:   (Omega).V1=(Omega).Lin(Rff) by VECTSP_9:28;
        Rf\{fn}\/{fnM} is linearly-independent by A174,A170,VECTSP11:40;
        hence RNG\/ rng ff is Basis of V1 by A184,A185,VECTSP_7:def 3;
        let i such that
A186:   i in dom ff and
A187:   i<= n1;
        per cases by A187,XXREAL_0:1;
        suppose
          i<n1;
          then ff.i=f.i & i<=n by FUNCT_7:32,NAT_1:13;
          hence thesis by A139,A179,A186;
        end;
        suppose
          i=n1;
          then ff.i=fnM by A179,A186,FUNCT_7:31;
          hence F.(ff.i) = F.(fn - Sum M) by VECTSP_6:46
            .= F.fn-F.(Sum M) by RANKNULL:8
            .= 0.V1 by A165,A167,A168,RLVECT_1:def 10;
        end;
      end;
    end;
A188: card (RNG\/C) = card RNG + card C - card (RNG/\C) by CARD_2:45
      .= card BAS-card (RNG/\C) by A128;
    then card (RNG\/C)+card (RNG/\C) =card BAS;
    then
A189: card (RNG\/C) <= card BAS by NAT_1:11;
A190: dim Lin BAS=card BAS by A4,VECTSP_9:26;
    then
A191: card (RNG\/C) >= card BAS by A130,A129,MATRLIN2:6;
    then
A192: card (RNG\/C) = card BAS by A189,XXREAL_0:1;
    dim V1= dim Lin(RNG\/C) by A130,A129,VECTSP_9:28;
    then
A193: RNG\/C is linearly-independent by A131,A190,A191,A189,MATRLIN2:5
,XXREAL_0:1;
A194: W[0]
    proof
      assume 0<= card C;
      card C=card Seg card C by FINSEQ_1:57;
      then Seg card C,C are_equipotent by CARD_1:5;
      then consider f be Function such that
A195: f is one-to-one and
A196: dom f = Seg card C and
A197: rng f = C by WELLORD2:def 4;
      reconsider f as FinSequence by A196,FINSEQ_1:def 2;
      reconsider f as FinSequence of V1 by A197,FINSEQ_1:def 4;
      take f;
      thus f is one-to-one & len f = card C by A195,A196,FINSEQ_1:def 3;
      RNG/\C={} by A188,A192;
      hence RNG misses rng f & RNG\/rng f is Basis of V1 by A129,A193,A197,
VECTSP_7:def 3,XBOOLE_0:def 7;
      let i;
      assume i in dom f & i<=0;
      hence thesis by FINSEQ_3:25;
    end;
    for n holds W[n] from NAT_1:sch 2(A194,A132);
    then consider f be FinSequence of V1 such that
A198: f is one-to-one and
A199: len f = card C and
A200: RNG misses rng f and
A201: RNG\/rng f is Basis of V1 and
A202: for i st i in dom f & i<= card C holds F.(f.i)=0.V1;
A203: rng (B^f)=rng B\/rng f by FINSEQ_1:31;
    now
      let x1,x2 be object such that
A204: x1 in dom B and
A205: x2 in dom B and
A206: B.x1 = B.x2;
      reconsider i1=x1,i2=x2 as Nat by A204,A205;
      r/.i1=r.i1 & r/.i2=r.i2 by A30,A59,A204,A205,PARTFUN1:def 6;
      then reconsider k1=r.i1,k2=r.i2 as Element of NAT;
A207: i1 -' k1 = Sum (LJ| (k1-'1)) implies F.(B.x1) = b1.(i1 -' k1+1)& i1
      -'k1+1 in dom b1 by A57,A59,A204;
A208: Q[i1,k1] by A29,A59,A204;
      then
A209: i1-'k1 =i1-k1 by XREAL_1:233;
A210: Q[i2,k2] by A29,A59,A205;
      then
A211: i2-'k2=i2-k2 by XREAL_1:233;
A212: k2-'1<=k2 by NAT_D:35;
A213: i1 -' k1 <> Sum (LJ| (k1-'1)) implies B.x1 = b1.(i1 -' k1) & i1-'k1
in dom b1 & min(LJ,i1-'k1)=k1 & (i1-'k1 < Sum (LJ|k1) implies F.(B.x1) = b1.(i1
-' k1+1) & i1 -' k1+1 in dom b1) & (i1-'k1 = Sum (LJ|k1) implies F.(B.x1) = 0.
      V1) by A57,A59,A204;
      k2 <= len LJ by A210,FINSEQ_3:25;
      then
A214: k2-'1 <=len LJ by A212,XXREAL_0:2;
      1<=k1 by A208,FINSEQ_3:25;
      then
A215: k1-'1=k1-1 by XREAL_1:233;
A216: i2 -' k2 <> Sum (LJ| (k2-'1)) implies B.x2 = b1.(i2 -' k2) & i2-'k2
in dom b1 & min(LJ,i2-'k2)=k2 & (i2-'k2 < Sum (LJ|k2) implies F.(B.x2) = b1.(i2
-' k2+1) & i2 -' k2+1 in dom b1) & (i2-'k2 = Sum (LJ|k2) implies F.(B.x2) = 0.
      V1) by A57,A59,A205;
      1<=k2 by A210,FINSEQ_3:25;
      then
A217: k2-'1=k2-1 by XREAL_1:233;
A218: i2 -' k2 = Sum (LJ| (k2-'1)) implies F.(B.x2) = b1.(i2 -' k2+1) &
      i2-'k2+1 in dom b1 by A57,A59,A205;
A219: k1-'1 <= k1 by NAT_D:35;
      k1<= len LJ by A208,FINSEQ_3:25;
      then
A220: k1-'1 <=len LJ by A219,XXREAL_0:2;
A221: dom LJ=dom J by MATRIXJ1:def 3;
      rng b1 is Basis of IM by MATRLIN:def 2;
      then
A222: rng b1 is linearly-independent Subset of IM by VECTSP_7:def 3;
A223: b1 is one-to-one by MATRLIN:def 2;
A224: i1-'k1 <= Sum (LJ|k1) & i2-'k2 <= Sum (LJ|k2) by A29,A59,A204,A205;
      now
        per cases by A224,XXREAL_0:1;
        suppose
A225:     i1 -' k1 = Sum (LJ| (k1-'1)) & i2 -' k2 = Sum (LJ| (k2-'1));
          then
A226:     F.(B.x2) = b1.(i2 -' k2+1) & i2-'k2+1 in dom b1 by A57,A59,A205;
          F.(B.x1) = b1.(i1 -' k1+1) & i1-'k1+1 in dom b1 by A57,A59,A204,A225;
          then
A227:     i1-'k1+1 = i2-'k2+1 by A206,A223,A226;
A228:     k2-'1 in dom LJ implies LJ.(k2-'1)<>0 by A7,A221;
          k1-'1 in dom LJ implies LJ.(k1-'1)<>0 by A7,A221;
          then k1-'1 = k2-'1 by A220,A214,A225,A227,A228,MATRIXJ1:11;
          hence i1=i2 by A215,A217,A209,A211,A227;
        end;
        suppose
A229:     i1 -' k1 = Sum (LJ| (k1-'1)) & i2 -' k2 <> Sum (LJ| (k2-'1))
          & i2-'k2 < Sum (LJ|k2);
          then
A230:     min(LJ,i2-'k2)=k2 by A57,A59,A205;
A231:     F.(B.x2) = b1.(i2-'k2+1) & i2-'k2+1 in dom b1 by A57,A59,A205,A229;
          F.(B.x1) = b1.(i1-'k1+1) & i1-'k1+1 in dom b1 by A57,A59,A204,A229;
          then
A232:     i1-'k1+1 = i2-'k2+1 by A206,A223,A231;
          k1-'1 <>0
          proof
            assume k1-'1=0;
            then LJ| (k1-'1)=<*>REAL;
            hence thesis by A29,A59,A205,A229,A232,RVSUM_1:72;
          end;
          then k1-'1 >=1 by NAT_1:14;
          then
A233:     k1-'1 in dom LJ by A220,FINSEQ_3:25;
          then LJ.(k1-'1)<>0 by A7,A221;
          hence i1=i2 by A229,A230,A232,A233,MATRIXJ1:6;
        end;
        suppose
          i1 -' k1 = Sum (LJ| (k1-'1)) & i2 -' k2 <> Sum (LJ| (k2-'1))
          & i2-'k2 = Sum (LJ|k2);
          then b1.(i1 -' k1+1) =0.IM & b1.(i1 -' k1+1) in rng b1 by A206,A207
,A216,FUNCT_1:def 3,VECTSP_4:11;
          hence i1 = i2 by A222,VECTSP_7:2;
        end;
        suppose
A234:     i2 -' k2 = Sum (LJ| (k2-'1)) & i1 -' k1 <> Sum (LJ| (k1-'1))
          & i1-'k1 < Sum (LJ|k1);
          then
A235:     min(LJ,i1-'k1)=k1 by A57,A59,A204;
A236:     F.(B.x1) = b1.(i1 -' k1+1) & i1-'k1+1 in dom b1 by A57,A59,A204,A234;
          F.(B.x2) = b1.(i2 -' k2+1) & i2-'k2+1 in dom b1 by A57,A59,A205,A234;
          then
A237:     i2-'k2+1 = i1-'k1+1 by A206,A223,A236;
          k2-'1 <>0
          proof
            assume k2-'1=0;
            then i1-'k1 =0 by A234,A237,RVSUM_1:72;
            hence thesis by A29,A59,A204,A234;
          end;
          then k2-'1 >=1 by NAT_1:14;
          then
A238:     k2-'1 in dom LJ by A214,FINSEQ_3:25;
          then LJ.(k2-'1)<>0 by A7,A221;
          hence i1=i2 by A234,A235,A237,A238,MATRIXJ1:6;
        end;
        suppose
          i2 -' k2 = Sum (LJ| (k2-'1)) & i1 -' k1 <> Sum (LJ| (k1-'1))
          & i1-'k1 = Sum (LJ|k1);
          then b1.(i2 -' k2+1) =0.IM & b1.(i2 -' k2+1) in rng b1 by A206,A213
,A218,FUNCT_1:def 3,VECTSP_4:11;
          hence i1= i2 by A222,VECTSP_7:2;
        end;
        suppose
A239:     i1 -' k1 <> Sum (LJ| (k1-'1)) & i2 -' k2 <> Sum (LJ| (k2-'1) );
          then i2-'k2 = i1-'k1 by A206,A213,A216,A223;
          then i2-k1=i1-k1 by A57,A59,A205,A213,A209,A211,A239;
          hence i1=i2;
        end;
      end;
      hence x1=x2;
    end;
    then B is one-to-one;
    then B^f is one-to-one by A198,A200,FINSEQ_3:91;
    then reconsider Bf=B^f as OrdBasis of V1 by A201,A203,MATRLIN:def 2;
    for i st i in dom Bf holds F.(Bf/.i) = 0.K * (Bf/.i) or i+1 in dom
    Bf & F.(Bf/.i) = 0.K * (Bf/.i) +Bf/.(i+1)
    proof
      let i such that
A240: i in dom Bf;
A241: Bf/.i=Bf.i by A240,PARTFUN1:def 6;
      per cases by A240,FINSEQ_1:25;
      suppose
A242:   i in dom B;
        then r/.i=r.i by A30,A59,PARTFUN1:def 6;
        then reconsider k=r.i as Element of NAT;
A243:   i-'k <= Sum (LJ|k) by A29,A59,A242;
A244:   Q[i,k] by A29,A59,A242;
        then 1<=k by FINSEQ_3:25;
        then k-'1=k-1 by XREAL_1:233;
        then k-'1+1=k;
        then LJ|k=(LJ| (k-'1))^<*LJ.k*> by A244,FINSEQ_5:10;
        then
A245:   dom LJ=dom J & Sum(LJ|k) = Sum (LJ| (k-'1))+LJ.k by MATRIXJ1:def 3
,RVSUM_1:74;
        per cases by A243,XXREAL_0:1;
        suppose
A246:     i -' k = Sum (LJ|k);
          then
A247:     i-'k <>Sum (LJ| (k-'1)) by A7,A244,A245;
          F.(Bf/.i) = F.(B.i) by A241,A242,FINSEQ_1:def 7
            .= 0.V1 by A57,A59,A242,A246,A247
            .= 0.K*(Bf/.i) by VECTSP_1:14;
          hence thesis;
        end;
        suppose
A248:     i -' k < Sum (LJ|k);
A249:     i -' k = Sum (LJ| (k-'1)) or i -' k <> Sum (LJ| (k-'1));
          then
A250:     F.(B.i)=b1.(i -' k+1) by A57,A59,A242,A248;
          dom J=dom LJ by MATRIXJ1:def 3;
          then
A251:     k <= L by A244,FINSEQ_3:25;
A252:     i-'k+1<=Sum(LJ|k) by A248,NAT_1:13;
A253:     i-'k=i-k by A244,XREAL_1:233;
A254:     i-'k+1 in dom b1 by A57,A59,A242,A248,A249;
          then
A255:     1<=i-'k+1 by FINSEQ_3:25;
          then
A256:     1+0<= i-k+1+k by A253,XREAL_1:7;
          i-'k+1<=S by A8,A254,FINSEQ_3:25;
          then i-k+1+k<=S+L by A251,A253,XREAL_1:7;
          then
A257:     i+1 in Seg(S+L) by A256;
          then r/.(i+1)=r.(i+1) by A30,PARTFUN1:def 6;
          then reconsider k1=r.(i+1) as Element of NAT;
          set i1=i+1;
A258:     dom B c= dom Bf by FINSEQ_1:26;
          1+k<=i-k+1+k by A255,A253,XREAL_1:7;
          then
A259:     k<=i+1 by NAT_1:13;
          then
A260:     i1-'k=i1-k by XREAL_1:233;
          Sum (LJ| (k-'1))<=i-'k+1 by A244,NAT_1:12;
          then
A261:     k<=k1 by A29,A244,A253,A257,A259,A260;
A262:     Q[i1,k1] by A29,A257;
A263:     k=k1
          proof
            assume
A264:       k<>k1;
            then
A265:       k<k1 by A261,XXREAL_0:1;
            then reconsider K1=k1-1 as Element of NAT by NAT_1:20;
A266:       i1-'k1 <= i1-'k by A261,NAT_D:41;
            i1-k1=i1-'k1 by A262,XREAL_1:233;
            then i1-'k1 <> i1-'k by A260,A264;
            then
A267:       i1-'k1 < i1-'k by A266,XXREAL_0:1;
A268:       k1=K1+1;
            then k<=K1 by A265,NAT_1:13;
            then
A269:       Sum(LJ|k)<=Sum(LJ|K1) by POLYNOM3:18;
            k1-'1=K1 by A268,NAT_D:34;
            then Sum(LJ|K1) <= i1-'k1 by A29,A257;
            then Sum(LJ|k)<= i1-'k1 by A269,XXREAL_0:2;
            hence thesis by A252,A253,A260,A267,XXREAL_0:2;
          end;
          Sum(LJ| (k-'1))<i-'k+1 by A244,NAT_1:13;
          then B.i1 = b1.(i -' k+1) by A57,A253,A257,A260,A263;
          then Bf.i1=b1.(i -' k+1) by A59,A257,FINSEQ_1:def 7;
          then Bf/.i1=b1.(i -' k+1) by A59,A257,A258,PARTFUN1:def 6;
          then F.(Bf/.i) = Bf/.i1 by A241,A242,A250,FINSEQ_1:def 7
            .= 0.V1+Bf/.i1 by RLVECT_1:def 4
            .= 0.K*(Bf/.i)+Bf/.i1 by VECTSP_1:14;
          hence thesis by A59,A257,A258;
        end;
      end;
      suppose
        ex j st j in dom f & i=len B + j;
        then consider j such that
A270:   j in dom f and
A271:   i=len B + j;
A272:   j<=len f by A270,FINSEQ_3:25;
        F.(Bf/.i) = F.(f.j) by A241,A270,A271,FINSEQ_1:def 7
          .= 0.V1 by A199,A202,A270,A272
          .= 0.K*(Bf/.i) by VECTSP_1:14;
        hence thesis;
      end;
    end;
    then consider
    J be non-empty FinSequence_of_Jordan_block of 0.K,K such that
A273: AutMt(F,Bf,Bf) = block_diagonal(J,0.K)by Th28;
    now
A274: dom (Len J)=dom J by MATRIXJ1:def 3;
      let i such that
A275: i in dom J;
      J.i<>{} by A275,FUNCT_1:def 9;
      hence (Len J).i <> 0 by A275,A274,MATRIXJ1:def 3;
    end;
    hence thesis by A273;
  end;
A276: P[0]
  proof
    reconsider J={} as FinSequence_of_Jordan_block of 0.K,K by Th10;
    let V1 be finite-dimensional VectSp of K;
    set b1 = the OrdBasis of V1;
    let F be nilpotent linear-transformation of V1,V1;
    assume deg F=0;
    then [#]V1 = {0.V1} by Th15
      .= the carrier of (0).V1 by VECTSP_4:def 3;
    then (0).V1 = (Omega).V1 by VECTSP_4:29;
    then
A277: 0 = dim V1 by VECTSP_9:29
      .= len b1 by MATRLIN2:21
      .= len AutMt(F,b1,b1) by MATRIX_0:def 2;
    take J,b1;
    thus AutMt(F,b1,b1) = {} by A277
      .= block_diagonal(J,0.K) by MATRIXJ1:22;
    thus thesis;
  end;
  for n holds P[n] from NAT_1:sch 2(A276,A1);
  then P[deg F];
  then consider
  J be FinSequence_of_Jordan_block of 0.K,K, b1 be OrdBasis of V1
  such that
A278: AutMt(F,b1,b1) = block_diagonal(J,0.K) and
A279: for i st i in dom J holds (Len J).i <> 0;
  now
    let x be object such that
A280: x in dom J;
    reconsider i=x as Element of NAT by A280;
    dom J=dom (Len J) & (Len J).i <> 0 by A279,A280,MATRIXJ1:def 3;
     then J.i is non empty by A280,MATRIXJ1:def 3;
    hence J.x is non empty;
  end;
  then J is non-empty;
  hence thesis by A278;
end;
