
theorem Th29:
for m be non zero Nat, X be non-empty m-element FinSequence,
 S be sigmaFieldFamily of X, M be sigmaMeasureFamily of S st M is sigma_finite
 holds Prod_Measure M is sigma_finite
proof
    defpred P[Nat] means
     for n be non zero Nat, X be non-empty n-element FinSequence,
       S be sigmaFieldFamily of X, M be sigmaMeasureFamily of S
     st M is sigma_finite & $1=n holds Prod_Measure M is sigma_finite;

A1: P[1]
    proof
     let n be non zero Nat, X be non-empty n-element FinSequence,
       S be sigmaFieldFamily of X, M be sigmaMeasureFamily of S;
     assume that
A2:   M is sigma_finite and
A3:   1 = n;

     1 in Seg n by A3; then
     consider Xi be non empty set, Fi being SigmaField of Xi,
      mi be sigma_Measure of Fi such that
A4:   Xi = X.1 & Fi = S.1 & mi = M.1 & mi is sigma_finite by A2;

A5:  CarProduct X = Xi by A4,A3,Def3;

     Prod_Field S = Fi by A4,A3,Def11;
     hence Prod_Measure M is sigma_finite by A4,A5,A3,Def13;
    end;

A6: for i be non zero Nat st P[i] holds P[i+1]
    proof
     let i be non zero Nat;
     assume A7:P[i];
     let k be non zero Nat, X be non-empty k-element FinSequence,
      S be sigmaFieldFamily of X, M be sigmaMeasureFamily of S;
     assume that
A8:   M is sigma_finite and
A9:  i+1 = k;

A10: ex Xi be non empty set, Fi being SigmaField of Xi,
       Mi be sigma_Measure of Fi st
      Xi = X.(i+1) & Fi = S.(i+1) &  Mi = M.(i+1)
    & Mi is sigma_finite by A8,A9,FINSEQ_1:4;

A11:  i < k by A9,NAT_1:13; then

A12:  SubFin(X,i) = X|i by Def5;
A13:  ElmFin(X,i+1) = X.(i+1) by A9,Def1;
A14: CarProduct X = [: CarProduct SubFin(X,i),ElmFin(X,i+1) :]
       by Th6,A9;

A15:  SubFin(S,i) = S|i by A11,Def6;
A16:  SubFin(M,i) = M|i by A11,Def9;
A17:  ElmFin(S,i+1) = S.(i+1) by A9,Def7;
A18:  ElmFin(M,i+1) = M.(i+1) by A9,Def10;

A19:  len X = k by CARD_1:def 7;
     SubFin(X,i+1) = X|k by A9,Def5; then
A20:  X = SubFin(X,i+1) by A19,FINSEQ_1:58;

A21: len S = k by CARD_1:def 7;
     SubFin(S,i+1) = S|k by A9,Def6; then
     S = SubFin(S,i+1) by A21,FINSEQ_1:58; then

A22:  Prod_Field S
      = sigma measurable_rectangles(Prod_Field SubFin(S,i),ElmFin(S,i+1))
        by A20,A9,A11,Th21;

     for j be Nat st j in Seg i holds
      ex Xj be non empty set, Fj being SigmaField of Xj,
        mj be sigma_Measure of Fj st
       Xj = SubFin(X,i).j & Fj = SubFin(S,i).j
     & mj = SubFin(M,i).j & mj is sigma_finite
     proof
      let j being Nat;
      assume A23: j in Seg i;
      Seg i c= Seg (i+1) by FINSEQ_1:5,NAT_1:12; then
      consider Xj be non empty set, Fj being SigmaField of Xj,
        mj be sigma_Measure of Fj such that
A24:   Xj = X.j & Fj = S.j & mj = M.j & mj is sigma_finite by A8,A9,A23;

      take Xj,Fj,mj;
      thus Xj = SubFin(X,i).j by A12,A23,A24,FUNCT_1:49;
      thus Fj = SubFin(S,i).j by A15,A23,A24,FUNCT_1:49;
      thus mj = SubFin(M,i).j by A16,A23,A24,FUNCT_1:49;
      thus thesis by A24;
     end; then
     SubFin(M,i) is sigma_finite; then
     Prod_Measure SubFin(M,i) is sigma_finite by A7; then
     Prod_Measure(Prod_Measure SubFin(M,i),ElmFin(M,i+1))
       is sigma_finite by A13,A17,A18,Th27,A10;
     hence Prod_Measure M is sigma_finite by A9,A14,Th28,A22;
    end;

    for k being non zero Nat holds P[k] from NAT_1:sch 10(A1,A6);
    hence thesis;
end;
