reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;

theorem Th29:
  for h be PartFunc of CNS1,CNS2, seq be sequence of CNS1 st rng
  seq c= dom h holds ||. h/*seq .|| = ||.h.||/*seq & -(h/*seq) = (-h)/*seq
proof
  let h be PartFunc of CNS1,CNS2;
  let seq be sequence of CNS1;
  assume
A1: rng seq c= dom h;
  then
A2: rng seq c= dom ||.h.|| by NORMSP_0:def 3;
  now
    let n;
    seq.n in rng seq by Th7;
    then seq.n in dom h by A1;
    then
A3: seq.n in dom ||.h.|| by NORMSP_0:def 3;
    thus ||.h/*seq.||.n = ||.(h/*seq).n.|| by NORMSP_0:def 4
      .= ||.h/.(seq.n).|| by A1,FUNCT_2:109
      .= ||.h.||.(seq.n) by A3,NORMSP_0:def 3
      .= ||.h.||/.(seq.n) by A3,PARTFUN1:def 6
      .= (||.h.||/*seq).n by A2,FUNCT_2:109;
  end;
  hence ||.h/*seq.|| = ||.h.||/*seq by FUNCT_2:63;
  thus -(h/*seq) =(-1r)*(h/*seq) by Th1
    .= ((-1r)(#)h)/*seq by A1,Th26
    .= (-h)/*seq by VFUNCT_2:23;
end;
