reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th29:
  for R being RelStr, x being Element of R, A being set holds A =
component x iff
  for y being object holds y in A iff [x,y] in EqCl the InternalRel of R
proof
  let R be RelStr;
  let x being Element of R;
  let A be set;
  set IR = the InternalRel of R;
A1: (for y being object
  holds y in A iff [x,y] in EqCl (the InternalRel of R))
  implies A = component x
  proof
    assume
A2: for y being object holds y in A iff [x,y] in EqCl (the InternalRel of R);
A3: component x c= A
    proof
      let a be object;
      assume a in component x;
      then [a,x] in EqCl IR by EQREL_1:19;
      then [x,a] in EqCl IR by EQREL_1:6;
      hence thesis by A2;
    end;
    A c= component x
    proof
      let a be object;
      assume a in A;
      then [x,a] in EqCl IR by A2;
      then [a,x] in EqCl IR by EQREL_1:6;
      hence thesis by EQREL_1:19;
    end;
    hence thesis by A3;
  end;
  A = component x implies
   for y being object holds [x,y] in EqCl IR implies y in A
  proof
    assume
A4: A = component x;
    let y be object;
    assume [x,y] in EqCl IR;
    then [y,x] in EqCl IR by EQREL_1:6;
    hence thesis by A4,EQREL_1:19;
  end;
  hence thesis by A1,Th28;
end;
