reserve S for Subset of TOP-REAL 2,
  C,C1,C2 for non empty compact Subset of TOP-REAL 2,
  p,q for Point of TOP-REAL 2;
reserve i,j,k for Nat,
  t,r1,r2,s1,s2 for Real;

theorem Th29:
  LSeg(SE-corner C,NE-corner C) /\ LSeg(SW-corner C,SE-corner C) =
  {SE-corner C}
proof
  for a being object holds a in LSeg(NE-corner C,SE-corner C) /\ LSeg(
  SE-corner C,SW-corner C) iff a = SE-corner C
  proof
    let a be object;
    thus a in LSeg(NE-corner C,SE-corner C) /\ LSeg(SE-corner C,SW-corner C)
    implies a = SE-corner C
    proof
      assume
A1:   a in LSeg(NE-corner C,SE-corner C) /\ LSeg(SE-corner C,SW-corner C);
      then a in LSeg(SE-corner C,SW-corner C) by XBOOLE_0:def 4;
      then
      a in {p : p`1 <= E-bound C & p`1 >= W-bound C & p`2 = S-bound C } by Th24
;
      then
A2:   ex p st p=a & p`1 <= E-bound C & p`1 >= W-bound C & p`2 = S-bound C;
      a in LSeg(NE-corner C,SE-corner C)by A1,XBOOLE_0:def 4;
      then
      a in {p : p`1 = E-bound C & p`2 <= N-bound C & p`2 >= S-bound C } by Th23
;
      then
      ex p st p = a & p`1 = E-bound C & p`2 <= N-bound C & p`2 >= S-bound C;
      hence thesis by A2,EUCLID:53;
    end;
    assume
A3: a = SE-corner C;
    then
A4: a in LSeg(SE-corner C,SW-corner C) by RLTOPSP1:68;
    a in LSeg(NE-corner C,SE-corner C) by A3,RLTOPSP1:68;
    hence thesis by A4,XBOOLE_0:def 4;
  end;
  hence thesis by TARSKI:def 1;
end;
