reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;

theorem Th29:
  for f being FinSequence of TOP-REAL 2, g,h being one-to-one
special FinSequence of TOP-REAL 2 st 2 <= len g & 2 <= len h & g is_a_h.c._for
  f & h is_a_v.c._for f holds L~g meets L~h
proof
  let f be FinSequence of TOP-REAL 2, g,h being one-to-one special FinSequence
  of TOP-REAL 2 such that
A1: 2 <= len g & 2 <= len h and
A2: for n st n in dom g holds W-bound L~f <= (g/.n)`1 & (g/.n)`1 <=
  E-bound L~f & S-bound L~f <= (g/.n)`2 & (g/.n)`2 <= N-bound L~f and
A3: (g/.1)`1 = W-bound L~f and
A4: (g/.len g)`1 = E-bound L~f and
A5: for n st n in dom h holds W-bound L~f <= (h/.n)`1 & (h/.n)`1 <=
  E-bound L~f & S-bound L~f <= (h/.n)`2 & (h/.n)`2 <= N-bound L~f and
A6: (h/.1)`2 = S-bound L~f and
A7: (h/.len h)`2 = N-bound L~f;
  reconsider g,h as non empty one-to-one special FinSequence of TOP-REAL 2 by
A1,CARD_1:27;
A8: X_axis(h) lies_between (X_axis(g)).1, (X_axis(g)).(len g)
  proof
    let n;
    set F = X_axis(g), r = (X_axis(g)).1, s = (X_axis(g)).(len g), H = X_axis
    h;
    assume n in dom H;
    then
A9: n in dom h & H.n = (h/.n)`1 by Th15,GOBOARD1:def 1;
    1 in dom F by FINSEQ_5:6;
    then r = W-bound L~f by A3,GOBOARD1:def 1;
    hence r <= H.n by A5,A9;
    len F = len g & len F in dom F by FINSEQ_5:6,GOBOARD1:def 1;
    then s = E-bound L~f by A4,GOBOARD1:def 1;
    hence thesis by A5,A9;
  end;
A10: Y_axis(h) lies_between (Y_axis(h)).1, (Y_axis(h)).(len h)
  proof
    let n;
    set F = Y_axis h, r = (Y_axis h).1, s = (Y_axis h).(len h);
    assume n in dom F;
    then
A11: n in dom h & F.n = (h/.n)`2 by Th16,GOBOARD1:def 2;
    1 in dom F by FINSEQ_5:6;
    then r = S-bound L~f by A6,GOBOARD1:def 2;
    hence r <= F.n by A5,A11;
    len F = len h & len F in dom F by FINSEQ_5:6,GOBOARD1:def 2;
    then s = N-bound L~f by A7,GOBOARD1:def 2;
    hence thesis by A5,A11;
  end;
A12: Y_axis(g) lies_between (Y_axis(h)).1, (Y_axis(h)).(len h)
  proof
    let n;
    set F = Y_axis(h), r = (Y_axis(h)).1, s = (Y_axis(h)).(len h), G = Y_axis
    g;
    assume n in dom G;
    then
A13: n in dom g & G.n = (g/.n)`2 by Th16,GOBOARD1:def 2;
    1 in dom F by FINSEQ_5:6;
    then r = S-bound L~f by A6,GOBOARD1:def 2;
    hence r <= G.n by A2,A13;
    len F = len h & len F in dom F by FINSEQ_5:6,GOBOARD1:def 2;
    then s = N-bound L~f by A7,GOBOARD1:def 2;
    hence thesis by A2,A13;
  end;
  X_axis(g) lies_between (X_axis(g)).1, (X_axis(g)).(len g)
  proof
    let n;
    set F = X_axis(g), r = (X_axis(g)).1, s = (X_axis(g)).(len g);
    assume n in dom F;
    then
A14: n in dom g & F.n = (g/.n)`1 by Th15,GOBOARD1:def 1;
    1 in dom F by FINSEQ_5:6;
    then r = W-bound L~f by A3,GOBOARD1:def 1;
    hence r <= F.n by A2,A14;
    len F = len g & len F in dom F by FINSEQ_5:6,GOBOARD1:def 1;
    then s = E-bound L~f by A4,GOBOARD1:def 1;
    hence thesis by A2,A14;
  end;
  hence thesis by A1,A8,A12,A10,GOBOARD4:5;
end;
