reserve X for set,
        D for a_partition of X,
        TG for non empty TopologicalGroup;
reserve A for Subset of X;
reserve US for UniformSpace;

theorem
  the topology of TopSpace_induced_by(right_uniformity(TG))
    = the topology of TG
  proof
    set X = the topology of FMT2TopSpace(FMT_induced_by(right_uniformity(TG))),
        Y = the topology of TG;
A2: X c= Y
    proof
      let x be object;
      assume x in X;
      then x in Family_open_set(FMT_induced_by(right_uniformity(TG)))
        by FINTOPO7:def 16;
      then consider y be open Subset of FMT_induced_by(right_uniformity(TG))
      such that
A3:   x = y;
      reconsider z = x as Subset of TG by A3;
      z is open
      proof
        now
          let t be Point of TG;
          assume
A4:       t in z;
          reconsider t1 = t as Point of FMT_induced_by(right_uniformity(TG));
A5:       y in U_FMT t1 by A3,A4,FINTOPO7:def 1;
          reconsider t2 = t1 as Element of right_uniformity(TG);
          z in Neighborhood t2 by A3,A5,UNIFORM2:def 14;
          then consider V0 be Element of the entourages of right_uniformity(TG)
          such that
A6:       z = Neighborhood(V0,t2);
          consider tg be Element of system_right_uniformity(TG) such that
A7:       tg c= V0 by CARDFIL2:def 8;
          tg in the set of all element_right_uniformity(U) where
            U is a_neighborhood of 1_TG;
          then consider U0 be a_neighborhood of 1_TG such that
A8:       tg = element_right_uniformity(U0);
          reconsider A = U0 * {t} as a_neighborhood of t by Th5;
          A c= z
          proof
            let u be object;
            assume u in A;
            then consider u0,u1 be Element of TG such that
A9:         u = u0 * u1 and
A10:        u0 in U0 and
A11:        u1 in {t};
            reconsider u2 = u as Element of TG by A9;
            u0 * 1_TG in U0 by A10,GROUP_1:def 4;
            then u0 * (t * t") in U0 by GROUP_1:def 5;
            then (u0 * t) * t" in U0 by GROUP_1:def 3;
            then u2 * t" in U0 by A9,A11,TARSKI:def 1;
            then [t,u2] in element_right_uniformity(U0);
            hence thesis by A6,A7,A8;
          end;
          hence ex A be Subset of TG st A is a_neighborhood of t & A c= z;
        end;
        hence thesis by CONNSP_2:7;
      end;
      hence x in Y;
    end;
    Y c= X
    proof
      let u be object;
      assume
A12:  u in Y;
      then reconsider u as Subset of TG;
      reconsider v = u as Subset of FMT_induced_by(right_uniformity(TG));
      for x being Element of FMT_induced_by(right_uniformity(TG)) st
      x in v holds v in U_FMT x
      proof
        let x be Element of FMT_induced_by(right_uniformity(TG));
        assume
A13:    x in v;
        reconsider t2 = x as Element of right_uniformity(TG);
        reconsider t3 = x as Element of TG;
        reconsider w = v as Subset of TG;
        now
          {t3"} = {t3}" by GROUP_2:3;
          then t3" in {t3}" by TARSKI:def 1;
          then t3 * t3" in w * {t3}" by A13;
          hence 1_TG in w * {t3}" by GROUP_1:def 5;
          w is open by A12;
          hence w * {t3}" is open;
        end;
        then reconsider U0 = w * {t3}" as a_neighborhood of 1_TG by CONNSP_2:6;
        element_right_uniformity(U0) in system_right_uniformity(TG);
        then reconsider V0 = element_right_uniformity(U0) as Element of
          the entourages of right_uniformity(TG) by CARDFIL2:def 8;
        v = {y where y is Element of TG: [t2,y] in V0}
        proof
          set v2 = {y where y is Element of TG: [t2,y] in V0};
A15:      v c= v2
          proof
            let t be object;
            assume
A16:        t in v;
            then reconsider t4 = t as Element of TG;
            {t3"} = {t3}" by GROUP_2:3;
            then t3" in {t3}" by TARSKI:def 1;
            then t4 * t3" in w * {t3}" by A16;
            then [t2,t4] in element_right_uniformity(U0);
            hence thesis;
          end;
          v2 c= v
          proof
            let t be object;
            assume t in v2;
            then consider y0 be Element of TG such that
A18:        t = y0 and
A19:        [t2,y0] in V0;
            consider xt,yt be Element of TG such that
A20:        [t2,y0] = [xt,yt] and
A21:        yt * xt" in U0 by A19;
            t2 = xt & y0 = yt by A20,XTUPLE_0:1;
            then consider u1,u2 be Element of TG such that
A22:        y0 * t3" = u1 * u2 and
A23:        u1 in w and
A24:        u2 in {t3}" by A21;
            {t3"} = {t3}" by GROUP_2:3;
            then u2 = t3" by A24,TARSKI:def 1;
            hence thesis by A22,A23,A18,GROUP_1:6;
          end;
          hence thesis by A15;
        end;
        then v = Neighborhood(V0,t2);
        then v in Neighborhood t2;
        hence thesis by UNIFORM2:def 14;
      end;
      then v is open;
      then u in Family_open_set(FMT_induced_by(right_uniformity(TG)));
      hence thesis by FINTOPO7:def 16;
    end;
    hence thesis by A2;
  end;
