
theorem Th2:
  for R being antisymmetric transitive non empty Relation, X being
finite Subset of field R st X <> {} ex x being Element of X st x is_maximal_wrt
  X, R
proof
  let R be antisymmetric transitive non empty Relation, X being finite Subset
  of field R;
  reconsider IR = R as Relation of field R by PRE_POLY:18;
  set S = RelStr(# field R, IR #);
  set CR = the carrier of S;
  set ir = the InternalRel of S;
A1: CR is non empty;
A2: R is_transitive_in field R by RELAT_2:def 16;
A3: S is transitive
  proof
    let x, y, z be Element of S;
    assume that
A4: x <= y and
A5: y <= z;
A6: [y,z] in ir by A5,ORDERS_2:def 5;
    [x,y] in ir by A4,ORDERS_2:def 5;
    then [x,z] in ir by A1,A2,A6;
    hence thesis by ORDERS_2:def 5;
  end;
A7: R is_antisymmetric_in field R by RELAT_2:def 12;
  S is antisymmetric
  proof
    let x, y be Element of S;
    assume that
A8: x <= y and
A9: y <= x;
A10: [y,x] in ir by A9,ORDERS_2:def 5;
    [x,y] in ir by A8,ORDERS_2:def 5;
    hence thesis by A1,A7,A10;
  end;
  then reconsider S as antisymmetric transitive non empty RelStr by A3;
  reconsider Y = X as finite Subset of CR;
  assume X <> {};
  then consider x being Element of S such that
A11: x in Y and
A12: x is_maximal_wrt Y, the InternalRel of S by BAGORDER:6;
  reconsider x as Element of X by A11;
  take x;
  thus x in X by A11;
  given y being set such that
A13: y in X and
A14: y <> x and
A15: [x, y] in R;
  thus thesis by A12,A13,A14,A15;
end;
