
theorem
  LMC31: for r be Real ex N be Nat
  st for n be Nat st N <=n holds r < n /log(2,n)
  proof
    let r0 be Real;
    ex r be Real st 0 < r & r0 <=r
    proof
      per cases;
      suppose A1:0 < r0;
        take r = r0;
        thus 0 < r & r0 <=r by A1;
      end;
      suppose A2:not 0 < r0;
        set r=1;
        take r;
        thus 0 < r & r0 <=r by A2;
      end;
    end; then
    consider r be Real such that
    AS: 0 < r & r0 <=r;
    set a0 = max(log(2,r),number_e);
    A01: log(2,r) <= a0 & number_e <= a0 by XXREAL_0:25;
    set k = [/ a0 \] + 1;
    a0 < k by INT_1:32; then
    k in NAT by INT_1:3,TAYLOR_1:11,A01; then
    reconsider k as Nat;
    A0: log(2,r) < k & number_e < k by A01,XXREAL_0:2,INT_1:32;
    2 to_power log(2,r) < 2 to_power k by A0,POWER:39; then
    A1:r < 2 to_power k by AS,POWER:def 3;
    consider N be Nat such that
    A2: for n be Nat st N<=n
    holds 2 to_power k <= n/log(2,n) by ASYMPT_2:13,A0;
    reconsider N as Element of NAT by ORDINAL1:def 12;
    take N;
    thus for n be Nat st N <=n holds r0 < n /log(2,n)
    proof
      let n be Nat;
      assume N<=n; then
      2 to_power k <= n/log(2,n) by A2; then
      r < n /log(2,n) by A1,XXREAL_0:2;
      hence r0 < n /log(2,n) by AS,XXREAL_0:2;
    end;
  end;
