
theorem Th2:
  for n be non zero Nat for F1,F2 be Tuple of n,BOOLEAN st Absval
  F1 = Absval F2 holds F1 = F2
proof
  defpred P[non zero Nat] means for F1,F2 be Tuple of $1,BOOLEAN st Absval F1
  = Absval F2 holds F1 = F2;
A1: for k be non zero Nat st P[k] holds P[k+1]
  proof
    let k be non zero Nat;
    assume
A2: for F1,F2 be Tuple of k,BOOLEAN st Absval F1 = Absval F2 holds F1 = F2;
    let F1,F2 be Tuple of k+1,BOOLEAN;
    consider T1 be Element of k-tuples_on BOOLEAN,
    d1 be Element of BOOLEAN such that
A3: F1 = T1^<*d1*> by FINSEQ_2:117;
    assume
A4: Absval F1 = Absval F2;
    consider T2 be Element of k-tuples_on BOOLEAN,
    d2 be Element of BOOLEAN such that
A5: F2 = T2^<*d2*> by FINSEQ_2:117;
A6: Absval T1 + IFEQ(d1,FALSE,0,2 to_power k) = Absval F1 by A3,BINARITH:20
      .= Absval T2 + IFEQ(d2,FALSE,0,2 to_power k) by A5,A4,BINARITH:20;
    d1 = d2
    proof
      assume
A7:   d1 <> d2;
      per cases by XBOOLEAN:def 3;
      suppose
A8:     d1 = FALSE;
        then
A9:     IFEQ(d1,FALSE,0 qua Real,2 to_power k) = 0 by FUNCOP_1:def 8;
        IFEQ(d2,FALSE,0 qua Real,2 to_power k) = 2 to_power k by A7,A8,
FUNCOP_1:def 8;
        hence contradiction by A6,A9,Th1,NAT_1:11;
      end;
      suppose
A10:    d1 = TRUE;
        then d2 = FALSE by A7,XBOOLEAN:def 3;
        then
A11:    IFEQ(d2,FALSE,0 qua Real,2 to_power k) = 0 by FUNCOP_1:def 8;
        IFEQ(d1,FALSE,0 qua Real,2 to_power k) = 2 to_power k by A10,
FUNCOP_1:def 8;
        hence contradiction by A6,A11,Th1,NAT_1:11;
      end;
    end;
    hence thesis by A2,A3,A5,A6,XCMPLX_1:2;
  end;
A12: P[1]
  proof
    let F1,F2 be Tuple of 1,BOOLEAN;
    consider d1 be Element of BOOLEAN such that
A13: F1 = <*d1*> by FINSEQ_2:97;
    assume
A14: Absval F1 = Absval F2;
    assume
A15: F1 <> F2;
    consider d2 be Element of BOOLEAN such that
A16: F2 = <*d2*> by FINSEQ_2:97;
    per cases by XBOOLEAN:def 3;
    suppose
A17:  d1 = FALSE;
      then
A18:  Absval F1 = 0 by A13,BINARITH:15;
      d2 = TRUE by A13,A16,A15,A17,XBOOLEAN:def 3;
      hence contradiction by A16,A14,A18,BINARITH:16;
    end;
    suppose
A19:  d1 = TRUE;
      then
A20:  Absval F1 = 1 by A13,BINARITH:16;
      d2 = FALSE by A13,A16,A15,A19,XBOOLEAN:def 3;
      hence contradiction by A16,A14,A20,BINARITH:15;
    end;
  end;
  thus for n being non zero Nat holds P[n] from NAT_1:sch 10(A12,A1);
end;
