reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem Th2:
for x being Element of REAL holds 1+x <= exp_R.x
proof
 let x be Element of REAL;
 per cases;
  suppose A1: x>0;
   reconsider 1x = 1+x as Element of REAL by XREAL_0:def 1;
   set B2 = NAT --> 1x;
   A2: for n being Nat st x>0 holds B2.n <= (Partial_Sums(x rExpSeq)).(n+1)
   proof
    let n be Nat;
    defpred J[Nat] means B2.$1 <= (Partial_Sums(x rExpSeq)).(1+$1);
    (Partial_Sums((x rExpSeq))).1
     = (Partial_Sums((x rExpSeq))).0 + ((x rExpSeq)).(0+1)
      by SERIES_1:def 1; then
    A3: (Partial_Sums(x rExpSeq)).1
     = (x rExpSeq).0 + (x rExpSeq).1 by SERIES_1:def 1;
A4:  (x rExpSeq).0 = x |^ 0 / (0!) by SIN_COS:def 5
         .= 1 by NEWTON:4,12;
     (x rExpSeq).1 = x |^ 1 / (1!) by SIN_COS:def 5; then
A5: J[0] by A4,A3,NEWTON:13;
A6: for k being Nat st J[k] holds J[k+1]
    proof
     let k be Nat;
     assume
A7:  J[k];
A8:  (Partial_Sums(x rExpSeq)).(1+(k+1))
      = (Partial_Sums(x rExpSeq)).((k+1)) + (x rExpSeq).((k+1)+1)
      by SERIES_1:def 1;
A9:  (x rExpSeq).((k+1)+1) > 0
     proof
      x |^ ((k+1)+1) > 0 & (((k+1)+1)!) > 0 by A1,NEWTON:83; then
      x |^ ((k+1)+1) / (((k+1)+1)!) >0;
      hence thesis by SIN_COS:def 5;
     end;
A10: 1+x<=(Partial_Sums(x rExpSeq)).(k+1) by A7,FUNCOP_1:7,ORDINAL1:def 12;
     (Partial_Sums(x rExpSeq)).(k+1)<=
      (x rExpSeq).((k+1)+1)+(Partial_Sums(x rExpSeq)).(k+1)
      by A9,XREAL_1:31;
     hence thesis by A8,A10,XXREAL_0:2;
    end;
    for k being Nat holds J[k] from NAT_1:sch 2(A5,A6);
    hence thesis;
   end;
A11: B2.n <= ((Partial_Sums(x rExpSeq))^\1).n
   proof
    B2.n <= (Partial_Sums(x rExpSeq)).(n+1) by A1,A2;
    hence thesis by NAT_1:def 3;
   end;
A12: lim B2 = B2.1 by SEQ_4:26 .= 1+x;
A13: Partial_Sums (x rExpSeq) is convergent
      by SERIES_1:def 2,SIN_COS:45; then
A14: lim ((Partial_Sums (x rExpSeq))^\1) =
          lim Partial_Sums (x rExpSeq) &
         (Partial_Sums (x rExpSeq))^\1 is convergent by SEQ_4:20;
   lim B2 <= lim ((Partial_Sums(x rExpSeq))^\1)
     by A13,A11,SEQ_2:18; then
   lim B2 <= Sum(x rExpSeq) by A14,SERIES_1:def 3;
   hence thesis by A12,SIN_COS:def 22;
   end;
   suppose x=0;
   hence thesis by SIN_COS:51;
   end;
   suppose A15: x<0;
    set y=-x;
    1-y <= exp_R.(-y)
    proof
      per cases;
       suppose A16: y<=1;
        for x being Element of REAL st x>0 & x<=1 holds
        1-x <= exp_R.(-x)
        proof
         let x be Element of REAL;
        assume that A17:x>0 and A18:x<=1;
        reconsider 1x = 1-x as Element of REAL by XREAL_0:def 1;
        set B2 = NAT --> 1x;
        A19: for n being Nat holds
             B2.n <= Partial_Sums ((-x) rExpSeq).(n+1)
        proof
         let n be Nat;
         defpred J[Nat] means
          B2.$1 <= Partial_Sums ((-x) rExpSeq).($1+1);
         Partial_Sums( (-x) rExpSeq ).(0+1) =
          Partial_Sums( (-x) rExpSeq ).0 + ( (-x) rExpSeq ).1
          by SERIES_1:def 1; then
         A20: Partial_Sums( (-x) rExpSeq ).(0+1) =
          ((-x) rExpSeq).0 + ( (-x) rExpSeq ).1 by SERIES_1:def 1;
         ((-x) rExpSeq).1 = (-x) |^ 1 / (1!) by SIN_COS:def 5; then
         A21: ((-x) rExpSeq).1 = (-x) by NEWTON:13;
         ((-x) rExpSeq).0 = (-x) |^ 0 / (0!) by SIN_COS:def 5
           .= 1 by NEWTON:4,12; then
A22:    J[0] by A21,A20;
A23:    for k being Nat st J[k] holds J[k+1]
         proof
          let k be Nat;
          assume
A24:      J[k];
          per cases;
           suppose k is even; then
           consider m being Nat such that A25: k=2*m by ABIAN:def 2;
A26: 1-x <= Partial_Sums( (-x) rExpSeq ).(k+1)
             by A24,FUNCOP_1:7,ORDINAL1:def 12;
           A27: for k being Element of NAT st k is even & k>0 holds
                   for y being Real holds (y rExpSeq).k >= 0
            proof
             let k be Element of NAT;
             assume that A28: k is even and A29: k>0;
             let y be Real;
             per cases;
              suppose y>0; then
                y |^k > 0 by NEWTON:83; then
                y |^ k / (k!) > 0;
                hence thesis by SIN_COS:def 5;
              end;
              suppose y=0; then y|^k=0 by A29,NEWTON:84; then
                y |^ k / (k!) = 0;
                hence thesis by SIN_COS:def 5;
              end;
              suppose A31:y<0;
                consider m being Nat such that
                A32: k=2*m by A28,ABIAN:def 2;
                y |^ k = y |^ (m+m) by A32;
                then y |^ k = y |^m * y |^m by NEWTON:8;
                then y |^ k = (y * y) |^m by NEWTON:7; then
                y |^k >=0 by A31,NEWTON:83; then
                y |^ k / (k!) >= 0;
                hence thesis by SIN_COS:def 5;
              end;
             end;
           ((-x) rExpSeq).(k+2) >= 0 by A25,A27; then
           A35: Partial_Sums( (-x) rExpSeq ).(k+1) <=
            (Partial_Sums( (-x) rExpSeq ).(k+1) + ((-x) rExpSeq).(k+2))
             by XREAL_1:31;
           1-x <= (Partial_Sums( (-x) rExpSeq ).(k+1) +
                   ((-x) rExpSeq).((k+1)+1)) by A26,A35,XXREAL_0:2;
           hence thesis by SERIES_1:def 1;
           end;
          suppose k is odd; then
           consider m being Nat such that A36: k=2*m+1 by ABIAN:9;
           for k being Element of NAT,x being Element of REAL st
                 k is odd & x>0 & x<=1 holds
                 1-x <= (Partial_Sums( (-x) rExpSeq )).k
                proof
                 let k be Element of NAT, x be Element of REAL;
                 assume A38: k is odd;
                 assume A39: x>0;
                 assume A40: x<=1;
                 defpred J[Nat] means
                  1-x <= (Partial_Sums( (-x) rExpSeq)).(2*$1+1);
                 (Partial_Sums( (-x) rExpSeq)).(2*0+1) =
                    (Partial_Sums( (-x) rExpSeq)).0 +
                     ( (-x) rExpSeq).1 by SERIES_1:def 1; then
                 A41: (Partial_Sums( (-x) rExpSeq)).(2*0+1) =
                     ( (-x) rExpSeq).0 +
                     ( (-x) rExpSeq).1 by SERIES_1:def 1;
A42:              ((-x) rExpSeq).0 = (-x) |^ 0 /(0!) by SIN_COS:def 5
                    .= 1 by NEWTON:4,12;
                 ((-x) rExpSeq).1 = (-x) |^ 1 /(1!) by SIN_COS:def 5; then
                 A44: J[0] by A41,A42,NEWTON:13;
                 A45: for k being Nat st J[k] holds J[k+1]
                 proof
                  let k be Nat;
                  assume A46:J[k];
                  (Partial_Sums( (-x) rExpSeq)).(2*k+1) <=
                    (Partial_Sums( (-x) rExpSeq)).(2*k+3)
                  proof
                   (Partial_Sums( (-x) rExpSeq)).(2*k+3)=
                    (Partial_Sums( (-x) rExpSeq)).(2*k+2) +
                     ((-x) rExpSeq).(2*k+2+1) by SERIES_1:def 1; then
                   (Partial_Sums( (-x) rExpSeq)).(2*k+3)=
                    (Partial_Sums( (-x) rExpSeq)).((2*k+1)+1) +
                     ( (-x) rExpSeq).(2*k+3); then
                   (Partial_Sums( (-x) rExpSeq)).(2*k+3)=
                    (Partial_Sums( (-x) rExpSeq)).(2*k+1)
                      + ( (-x) rExpSeq).(2*k+2)
                      + ( (-x) rExpSeq).(2*k+3) by SERIES_1:def 1; then
                   A47: (Partial_Sums( (-x) rExpSeq)).(2*k+3)=
                    (Partial_Sums( (-x) rExpSeq)).(2*k+1)
                      + (( (-x) rExpSeq).((2*k)+2)
                      + ( (-x) rExpSeq).((2*k)+3));
                   (((-x) rExpSeq).((2*k+1)+1) +
                    ((-x) rExpSeq).((2*k+1)+2) ) >= 0 by A39,A40,Th1;
                   hence thesis by A47,XREAL_1:31;
                  end;
                  hence thesis by A46,XXREAL_0:2;
                 end;
                 A48: for k being Nat holds J[k] from NAT_1:sch 2(A44,A45);
                 consider m being Nat such that A49: k=2*m+1
                   by A38,ABIAN:9;
                 thus thesis by A48,A49;
                end;
           hence thesis by A36,A17,A18;
         end;
        end;
        for k being Nat holds J[k] from NAT_1:sch 2(A22,A23);
        hence thesis;
        end;
A50: for n being Nat holds
              B2.n <= ((Partial_Sums( (-x) rExpSeq ))^\1).n
         proof
          let n be Nat;
          B2.n <= Partial_Sums( (-x) rExpSeq ).(n+1) by A19;
          hence thesis by NAT_1:def 3;
         end;
        A51: lim B2 = B2.1 by SEQ_4:26 .= 1-x;
       A52: Partial_Sums ((-x) rExpSeq) is convergent
          by SERIES_1:def 2,SIN_COS:45; then
       A53: lim ((Partial_Sums ((-x) rExpSeq))^\1) =
                      lim Partial_Sums ((-x) rExpSeq) &
              (Partial_Sums ((-x) rExpSeq))^\1 is convergent by SEQ_4:20;
        lim B2 <= lim ((Partial_Sums((-x) rExpSeq))^\1)
          by A52,A50,SEQ_2:18; then
        lim B2 <= Sum((-x) rExpSeq) by A53,SERIES_1:def 3;
       hence thesis by A51,SIN_COS:def 22;
       end;
       hence thesis by A15,A16;
      end;
      suppose A54: y>1; then
      0 < exp_R.(-y) by SIN_COS:53;
      hence thesis by A54,XREAL_1:49;
      end;
    end;
    hence thesis;
  end;
end;
