reserve Y for non empty set,
  G for Subset of PARTITIONS(Y),
  A,B,C,D,E,F for a_partition of Y;

theorem
  G={A,B} & A<>B implies '/\' G = A '/\' B
proof
  assume that
A1: G={A,B} and
A2: A<>B;
A3: A '/\' B c= '/\' G
  proof
    let x be object;
     reconsider xx=x as set by TARSKI:1;
    assume
A4: x in A '/\' B;
    then
A5: x<>{} by EQREL_1:def 4;
    x in INTERSECTION(A,B) \ {{}} by A4,PARTIT1:def 4;
    then consider a,b being set such that
A6: a in A and
A7: b in B and
A8: x = a /\ b by SETFAM_1:def 5;
    set h0=(A,B) --> (a,b);
A9: rng((A,B) --> (a,b)) = {a,b} by A2,FUNCT_4:64;
    rng h0 c= bool Y
    proof
      let y be object;
      assume
A10:  y in rng h0;
      now
        per cases by A9,A10,TARSKI:def 2;
        case
          y=a;
          hence thesis by A6;
        end;
        case
          y=b;
          hence thesis by A7;
        end;
      end;
      hence thesis;
    end;
    then reconsider F=rng h0 as Subset-Family of Y;
A11: xx c= Intersect F
    proof
      let u be object;
      assume
A12:  u in xx;
      for y be set holds y in F implies u in y
      proof
        let y be set;
        assume
A13:    y in F;
        now
          per cases by A9,A13,TARSKI:def 2;
          case
            y=a;
            hence thesis by A8,A12,XBOOLE_0:def 4;
          end;
          case
            y=b;
            hence thesis by A8,A12,XBOOLE_0:def 4;
          end;
        end;
        hence thesis;
      end;
      then u in meet F by A9,SETFAM_1:def 1;
      hence thesis by A9,SETFAM_1:def 9;
    end;
A14: for d being set st d in G holds h0.d in d
    proof
      let d be set;
      assume
A15:  d in G;
      now
        per cases by A1,A15,TARSKI:def 2;
        case
          d=A;
          hence thesis by A2,A6,FUNCT_4:63;
        end;
        case
          d=B;
          hence thesis by A7,FUNCT_4:63;
        end;
      end;
      hence thesis;
    end;
A16: rng h0 = {a,b} by A2,FUNCT_4:64;
    Intersect F c= xx
    proof
      let u be object;
      assume
A17:  u in Intersect F;
A18:  a in {a,b} by TARSKI:def 2;
      then a in F by A2,FUNCT_4:64;
      then
A19:  Intersect F = meet F by SETFAM_1:def 9;
      b in {a,b} by TARSKI:def 2;
      then
A20:  u in b by A16,A17,A19,SETFAM_1:def 1;
      u in a by A16,A17,A18,A19,SETFAM_1:def 1;
      hence thesis by A8,A20,XBOOLE_0:def 4;
    end;
    then dom((A,B) --> (a,b)) = {A,B} & x = Intersect F by A11,FUNCT_4:62
,XBOOLE_0:def 10;
    hence thesis by A1,A14,A5,BVFUNC_2:def 1;
  end;
  '/\' G c= A '/\' B
  proof
    let x be object;
     reconsider xx=x as set by TARSKI:1;
    assume x in '/\' G;
    then consider h being Function, F being Subset-Family of Y such that
A21: dom h=G and
A22: rng h = F and
A23: for d being set st d in G holds h.d in d and
A24: x=Intersect F and
A25: x<>{} by BVFUNC_2:def 1;
A26: not x in {{}} by A25,TARSKI:def 1;
    A in dom h by A1,A21,TARSKI:def 2;
    then
A27: h.A in rng h by FUNCT_1:def 3;
A28: h.A /\ h.B c= xx
    proof
      let m be object;
      assume
A29:  m in h.A /\ h.B;
A30:  rng h c= {h.A,h.B}
      proof
        let u be object;
        assume u in rng h;
        then consider x1 being object such that
A31:    x1 in dom h and
A32:    u = h.x1 by FUNCT_1:def 3;
        now
          per cases by A1,A21,A31,TARSKI:def 2;
          case
            x1=A;
            hence thesis by A32,TARSKI:def 2;
          end;
          case
            x1=B;
            hence thesis by A32,TARSKI:def 2;
          end;
        end;
        hence thesis;
      end;
      for y being set holds y in rng h implies m in y
      proof
        let y be set;
        assume
A33:    y in rng h;
        now
          per cases by A30,A33,TARSKI:def 2;
          case
            y=h.A;
            hence thesis by A29,XBOOLE_0:def 4;
          end;
          case
            y=h.B;
            hence thesis by A29,XBOOLE_0:def 4;
          end;
        end;
        hence thesis;
      end;
      then m in meet (rng h) by A27,SETFAM_1:def 1;
      hence thesis by A22,A24,A27,SETFAM_1:def 9;
    end;
    B in G by A1,TARSKI:def 2;
    then
A34: h.B in B by A23;
    A in G by A1,TARSKI:def 2;
    then
A35: h.A in A by A23;
    B in dom h by A1,A21,TARSKI:def 2;
    then
A36: h.B in rng h by FUNCT_1:def 3;
    xx c= h.A /\ h.B
    proof
      let m be object;
      assume m in xx;
      then m in meet (rng h) by A22,A24,A27,SETFAM_1:def 9;
      then m in h.A & m in h.B by A27,A36,SETFAM_1:def 1;
      hence thesis by XBOOLE_0:def 4;
    end;
    then h.A /\ h.B = x by A28,XBOOLE_0:def 10;
    then x in INTERSECTION(A,B) by A35,A34,SETFAM_1:def 5;
    then x in INTERSECTION(A,B) \ {{}} by A26,XBOOLE_0:def 5;
    hence thesis by PARTIT1:def 4;
  end;
  hence thesis by A3,XBOOLE_0:def 10;
end;
