reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem Th2:
  (seq1 + seq2)*Ns = (seq1*Ns) + (seq2*Ns) & (seq1 - seq2)*Ns = (
  seq1*Ns) - (seq2*Ns) & (seq1 (#) seq2)*Ns = (seq1*Ns) (#) (seq2*Ns)
proof
  now
    let n be Element of NAT;
    thus ((seq1 + seq2)*Ns).n = (seq1 + seq2).(Ns.n) by FUNCT_2:15
      .= seq1.(Ns.n) + seq2.(Ns.n) by VALUED_1:1
      .= (seq1*Ns).n + seq2.(Ns.n) by FUNCT_2:15
      .= (seq1*Ns).n + (seq2*Ns).n by FUNCT_2:15
      .= (seq1*Ns + seq2*Ns).n by VALUED_1:1;
  end;
  hence (seq1 + seq2)*Ns = (seq1*Ns) + (seq2*Ns) by FUNCT_2:63;
  now
    let n be Element of NAT;
    thus ((seq1 - seq2)*Ns).n = (seq1 - seq2).(Ns.n) by FUNCT_2:15
      .= seq1.(Ns.n) - seq2.(Ns.n) by Th1
      .= (seq1*Ns).n - seq2.(Ns.n) by FUNCT_2:15
      .= (seq1*Ns).n - (seq2*Ns).n by FUNCT_2:15
      .= (seq1*Ns - seq2*Ns).n by Th1;
  end;
  hence (seq1 - seq2)*Ns = (seq1*Ns) - (seq2*Ns) by FUNCT_2:63;
  now
    let n be Element of NAT;
    thus ((seq1 (#) seq2)*Ns).n = (seq1 (#) seq2).(Ns.n) by FUNCT_2:15
      .= seq1.(Ns.n) * seq2.(Ns.n) by VALUED_1:5
      .= (seq1*Ns).n * seq2.(Ns.n) by FUNCT_2:15
      .= (seq1*Ns).n * (seq2*Ns).n by FUNCT_2:15
      .= ((seq1*Ns)(#)(seq2*Ns)).n by VALUED_1:5;
  end;
  hence thesis by FUNCT_2:63;
end;
