reserve x,y,y1,y2,z,e,s for set;
reserve alpha,beta,gamma for Ordinal;
reserve n,m,k for Nat;

theorem Th2:
  ConwayDay(0) = { ConwayZero }
proof
A1:
  ConwayDay(0) c= { ConwayZero }
  proof
    let z be object;
    assume z in ConwayDay(0);
    then consider w being strict left-right such that
A2:   z = w & for e st e in (the LeftOptions of w) \/ (the RightOptions of w)
        ex beta st beta in 0 & e in ConwayDay(beta) by Th1;

    (the LeftOptions of w) \/ (the RightOptions of w) = {}
    proof
      assume not thesis;
      then consider e being object such that
A3:     e in (the LeftOptions of w) \/ (the RightOptions of w)
        by XBOOLE_0:def 1;
      ex beta st beta in 0 & e in ConwayDay(beta) by A2,A3;
      hence contradiction;
    end;
    then the LeftOptions of w = {} & the RightOptions of w = {};
    hence z in { ConwayZero } by A2,TARSKI:def 1;
  end;
  for e st e in {} \/ {} ex beta st beta in 0 & e in ConwayDay(beta);
  then ConwayZero in ConwayDay(0) by Th1;
  then { ConwayZero } c= ConwayDay(0) by ZFMISC_1:31;
  hence thesis by A1,XBOOLE_0:def 10;
end;
