reserve IIG for monotonic Circuit-like non void non empty ManySortedSign;

theorem Th2:
  for A being non-empty Circuit of IIG, iv being InputValues of A,
  v being Vertex of IIG, e being Element of (the Sorts of FreeEnv A).v, x being
  set st v in InnerVertices IIG \ SortsWithConstants IIG & e = root-tree[x,v]
  holds (Fix_inp_ext iv).v.e = e
proof
  let A be non-empty Circuit of IIG, iv be InputValues of A, v be Vertex of
  IIG, e be Element of (the Sorts of FreeEnv A).v, x be set such that
A1: v in InnerVertices IIG \ SortsWithConstants IIG and
A2: e = root-tree[x,v];
A3: e.{} = [x,v] by A2,TREES_4:3;
A4: now
    given o being OperSymbol of IIG such that
A5: [o,the carrier of IIG] = e.{} and
    the_result_sort_of o = v;
    v = the carrier of IIG by A3,A5,XTUPLE_0:1;
    hence contradiction by Lm1;
  end;
  set X = the Sorts of A;
  FreeEnv A = MSAlgebra (# FreeSort the Sorts of A, FreeOper the Sorts of
    A #) by MSAFREE:def 14;
  then e in (FreeSort X).v;
  then
A6: e in FreeSort(X,v) by MSAFREE:def 11;
  Fix_inp iv c= Fix_inp_ext iv by Def2;
  then
A7: (Fix_inp iv).v c= (Fix_inp_ext iv).v;
  FreeSort(X,v) = {a where a is Element of TS(DTConMSA(X)): (ex x being
set st x in X.v & a = root-tree[x,v]) or ex o being OperSymbol of IIG st [o,the
  carrier of IIG] = a.{} & the_result_sort_of o = v} by MSAFREE:def 10;
  then
  ex a being Element of TS(DTConMSA(X)) st a = e &( (ex x being set st x in
X.v & a = root-tree[x,v]) or ex o being OperSymbol of IIG st [o,the carrier of
  IIG] = a.{} & the_result_sort_of o = v) by A6;
  then
A8: e in FreeGen(v, the Sorts of A) by A4,MSAFREE:def 15;
  then e in (FreeGen the Sorts of A).v by MSAFREE:def 16;
  then e in dom((Fix_inp iv).v) by FUNCT_2:def 1;
  hence (Fix_inp_ext iv).v.e = (Fix_inp iv).v.e by A7,GRFUNC_1:2
    .= (id FreeGen(v, the Sorts of A)).e by A1,Def1
    .= e by A8,FUNCT_1:17;
end;
