
theorem
  for C being FormalContext for a being Attribute of C holds (
AttributeDerivation(C)).({a}) = {o where o is Object of C : o is-connected-with
  a}
proof
  let C be FormalContext;
  let a be Attribute of C;
  {a} c= the carrier' of C
  proof
    let x be object;
    assume x in {a};
    then x = a by TARSKI:def 1;
    hence thesis;
  end;
  then reconsider t = {a} as Subset of the carrier' of C;
A1: for x being object holds x in {o where o is Object of C : for a9 being
Attribute of C st a9 in t holds o is-connected-with a9} implies x in {o where o
  is Object of C : o is-connected-with a}
  proof
    set a9 = the Element of t;
    let x be object;
    reconsider a9 as Attribute of C by TARSKI:def 1;
A2: a9 = a by TARSKI:def 1;
    assume x in {o where o is Object of C : for a9 being Attribute of C st a9
    in t holds o is-connected-with a9};
    then
A3: ex x9 being Object of C st x9 = x & for a9 being Attribute of C st a9
    in t holds x9 is-connected-with a9;
    then reconsider x as Object of C;
    x is-connected-with a9 by A3;
    hence thesis by A2;
  end;
A4: for x being object holds x in {o where o is Object of C : o
  is-connected-with a} implies x in {o where o is Object of C : for a9 being
  Attribute of C st a9 in t holds o is-connected-with a9}
  proof
    let x be object;
    assume x in {o where o is Object of C : o is-connected-with a};
    then
A5: ex x9 being Object of C st x9 = x & x9 is-connected-with a;
    then reconsider x as Object of C;
    for a9 being Attribute of C st a9 in t holds x is-connected-with a9
    by A5,TARSKI:def 1;
    hence thesis;
  end;
  (AttributeDerivation(C)).t = {o where o is Object of C : for a9 being
  Attribute of C st a9 in t holds o is-connected-with a9} by Def3;
  hence thesis by A1,A4,TARSKI:2;
end;
