
theorem Th2:
  for x,y,z being Point of Complex_l2_Space for a be Complex holds
  ( x.|.x = 0 iff x = 0.Complex_l2_Space ) & Re(x.|.x) >= 0 & Im(x.|.x) = 0 & x
  .|.y = (y.|.x)*' & (x+y).|.z = x.|.z + y.|.z & (a*x).|.y = a*(x.|.y)
proof
  let x, y, z be Point of Complex_l2_Space;
  let a be Complex;
  set seqx = seq_id(x);
A1: x .|. x = Sum(seqx(#)seqx*') by CSSPACE:def 17;
A2: seqx(#)seqx*' is absolutely_summable by Lm19;
  then Sum(seqx(#)seqx*') = Sum(Re(seqx(#)seqx*'))+Sum(Im(seqx(#)seqx*'))*<i>
  by COMSEQ_3:53;
  then
A3: Re(x.|.x) = Sum(Re(seqx(#)seqx*')) & Im(x.|.x) = Sum(Im(seqx(#)seqx*'))
  by A1,COMPLEX1:12;
A4: now
    set seq = seq_id(x);
A5: x .|. x = Sum(seq_id(x)(#)(seq_id(x))*') by CSSPACE:def 17;
    set rseq = Re(seq(#)seq*');
A6: for n be Nat holds rseq.n = (Re(seq.n))^2 + (Im(seq.n))^2
    proof
      let n be Nat;
A7:  n in NAT by ORDINAL1:def 12;
      rseq.n = ( Re seq (#) Re (seq*') -Im seq (#) Im (seq*') ).n by
COMSEQ_3:21
        .= ( Re seq (#) Re (seq*') ).n + ( -Im seq (#) Im (seq*') ).n by
SEQ_1:7
        .= ( Re seq (#) Re (seq*') ).n + -( (Im seq (#) Im (seq*'))).n by
SEQ_1:10
        .= ( Re seq (#) Re (seq*') ).n - ( (Im seq (#) Im (seq*'))).n
        .= (Re seq).n * (Re (seq*')).n - ((Im seq (#) Im (seq*'))).n by SEQ_1:8
        .= (Re seq).n * (Re (seq*')).n - ((Im seq).n * (Im (seq*')).n) by
SEQ_1:8
        .= Re (seq.n) * (Re (seq*')).n - ((Im seq).n * (Im (seq*')).n) by
COMSEQ_3:def 5
        .= Re (seq.n) * Re (seq*'.n) - ((Im seq).n * (Im (seq*')).n) by
COMSEQ_3:def 5
        .= Re (seq.n) * Re (seq*'.n) - (Im(seq.n) * (Im (seq*')).n) by
COMSEQ_3:def 6
        .= Re (seq.n) * Re (seq*'.n) - (Im(seq.n) * Im (seq*'.n)) by
COMSEQ_3:def 6
        .= Re (seq.n) * Re ((seq.n)*') - (Im(seq.n) * Im (seq*'.n)) by
COMSEQ_2:def 2,A7
        .= Re (seq.n) * Re ((seq.n)*') - (Im(seq.n) * Im((seq.n)*')) by
COMSEQ_2:def 2,A7
        .= Re (seq.n) * Re (seq.n) - (Im(seq.n) * Im((seq.n)*')) by COMPLEX1:27
        .= Re(seq.n) * Re(seq.n) - (Im(seq.n) * -Im(seq.n)) by COMPLEX1:27
        .= (Re(seq.n))^2 + Im(seq.n) * Im(seq.n);
      hence thesis;
    end;
A8: for n be Nat holds 0 <= rseq.n
    proof
      let n be Nat;
A9:   (Im(seq.n))^2 >= 0 by XREAL_1:63;
      rseq.n = (Re(seq.n))^2 + (Im(seq.n))^2 & (Re(seq.n))^2 >= 0 by A6,
XREAL_1:63;
      then rseq.n >= 0 + 0 by A9;
      hence thesis;
    end;
A10: seq_id(x)(#)(seq_id(x))*' is absolutely_summable by Lm19;
    assume x .|. x = 0;
    then
    Sum(Re(seq_id(x)(#)(seq_id(x))*'))+ (Sum(Im(seq_id(x)(#)(seq_id(x))*')
    ))*<i> = 0 by A5,A10,COMSEQ_3:53;
    then
A11: Sum(Re(seq_id(x)(#)(seq_id(x))*')) = 0 by COMPLEX1:4,12;
A12: for n be Nat holds (seq_id(x)).n = 0
    proof
      let n be Nat;
      rseq.n = (Re(seq.n))^2 + (Im(seq.n))^2 by A6;
      then (Re(seq.n))^2 + (Im(seq.n))^2 = 0 by A10,A11,A8,RSSPACE:17;
      hence thesis by COMPLEX1:5;
    end;
    x is Element of the_set_of_ComplexSequences by CSSPACE:def 11;
    hence x=0.Complex_l2_Space by A12,Lm10,CSSPACE:5;
  end;
A13: now
    assume
A14: x=0.Complex_l2_Space;
A15: for n be Nat holds (seq_id(x)(#)(seq_id(x))*').n=0
    proof
      let n be Nat;
      thus (seq_id(x)(#)(seq_id(x))*').n = (seq_id(x)).n * ((seq_id(x))*').n
      by VALUED_1:5
        .=0c * ((seq_id(x))*').n by A14,Lm10,CSSPACE:4
        .= 0;
    end;
    thus x.|.x = Sum(seq_id(x)(#)(seq_id(x))*') by CSSPACE:def 17
      .=0 by A15,CSSPACE:80;
  end;
  set seqy = seq_id(y);
A16: for n being Nat holds 0 <= (Re(seqx(#)seqx*')).n
  proof
    let n be Nat;
A17:  n in NAT by ORDINAL1:def 12;
A18: (Re(seqx.n))^2 >= 0 & (Im(seqx.n))^2 >= 0 by XREAL_1:63;
    (Re(seqx(#)seqx*')).n = Re((seqx(#)seqx*').n) by COMSEQ_3:def 5
      .= Re( seqx.n * seqx*'.n ) by VALUED_1:5
      .= Re( seqx.n * (seqx.n)*') by COMSEQ_2:def 2,A17
      .= (Re(seqx.n))^2 + (Im(seqx.n))^2 by COMPLEX1:40;
    then (Re(seqx(#)seqx*')).n >= 0 + 0 by A18;
    hence thesis;
  end;
  |.seqx.|(#)|.seqy.| is summable by Lm16;
  then |.seqx*'.|(#)|.seqy.| is summable by Lm18;
  then |.seqx*'(#)seqy.| is summable by COMSEQ_1:46;
  then
A19: seqx*'(#)seqy is absolutely_summable by COMSEQ_3:def 9;
  set seqz = seq_id(z);
A20: for n being Nat holds (Im(seqx(#)seqx*')).n = 0
  proof
    let n be Nat;
A21:  n in NAT by ORDINAL1:def 12;
    (Im(seqx(#)seqx*')).n = Im((seqx(#)seqx*').n) by COMSEQ_3:def 6
      .= Im( seqx.n * seqx*'.n ) by VALUED_1:5
      .= Im( seqx.n * (seqx.n)*') by COMSEQ_2:def 2,A21;
    hence thesis by COMPLEX1:40;
  end;
  |.seqx.|(#)|.seqz.| is summable by Lm16;
  then |.seqx.|(#)|.seqz*'.| is summable by Lm18;
  then |.seqx(#)seqz*'.| is summable by COMSEQ_1:46;
  then
A22: seqx(#)seqz*' is absolutely_summable by COMSEQ_3:def 9;
  |.seqy.|(#)|.seqz.| is summable by Lm16;
  then |.seqy.|(#)|.seqz*'.| is summable by Lm18;
  then |.seqy(#)seqz*'.| is summable by COMSEQ_1:46;
  then
A23: seqy(#)seqz*' is absolutely_summable by COMSEQ_3:def 9;
A24: (x+y).|.z = Sum(seq_id(x+y)(#)seqz*') by CSSPACE:def 17
    .= Sum(seq_id(seqx+seqy)(#)seqz*') by Lm12
    .= Sum(seqx(#)seqz*'+seqy(#)seqz*') by COMSEQ_1:10
    .= Sum(seqx(#)seqz*')+Sum(seqy(#)seqz*') by A22,A23,COMSEQ_3:54
    .=(the scalar of Complex_l2_Space).(x,z)+Sum(seqy(#)seqz*') by
CSSPACE:def 17
    .= x.|.z + y.|.z by CSSPACE:def 17;
  |.seqx.|(#)|.seqy.| is summable by Lm16;
  then |.seqx.|(#)|.seqy*'.| is summable by Lm18;
  then |.seqx(#)seqy*'.| is summable by COMSEQ_1:46;
  then
A25: seqx(#)seqy*' is absolutely_summable by COMSEQ_3:def 9;
A26: (a*x).|.y =Sum(seq_id(a*x)(#)seqy*') by CSSPACE:def 17
    .=Sum(seq_id(a(#)seqx)(#)seqy*') by Lm13
    .=Sum(a(#)(seqx(#)seqy*')) by COMSEQ_1:12
    .=a*Sum(seqx(#)seqy*') by A25,COMSEQ_3:56
    .=a*(x.|.y) by CSSPACE:def 17;
  x .|. y = Sum((seqx*')*'(#)seqy*') by CSSPACE:def 17
    .= Sum( (seqx*'(#)seqy)*' ) by COMSEQ_2:5
    .= (Sum (seqx*'(#)seqy) )*' by A19,Lm5
    .=(y .|. x)*' by CSSPACE:def 17;
  hence thesis by A4,A13,A2,A3,A16,A20,A24,A26,RSSPACE:16,SERIES_1:18;
end;
