
theorem Th2:
  the carrier of Complex_linfty_Space =
  the_set_of_BoundedComplexSequences & ( for x be set holds x is VECTOR of
  Complex_linfty_Space iff x is Complex_Sequence & seq_id x is bounded ) & 0.
  Complex_linfty_Space = CZeroseq & ( for u be VECTOR of Complex_linfty_Space
holds u = seq_id u ) & ( for u,v be VECTOR of Complex_linfty_Space holds u+v =
seq_id(u)+seq_id(v) ) & ( for c be Complex, u be VECTOR of Complex_linfty_Space
holds c*u =c(#)seq_id(u) ) & ( for u be VECTOR of Complex_linfty_Space holds -u
  = -seq_id u & seq_id(-u) = -seq_id u ) & ( for u,v be VECTOR of
  Complex_linfty_Space holds u-v =seq_id(u)-seq_id(v) ) & ( for v be VECTOR of
  Complex_linfty_Space holds seq_id v is bounded ) & for v be VECTOR of
  Complex_linfty_Space holds ||.v.|| = upper_bound rng |.seq_id v.|
proof
  set l1 =Complex_linfty_Space;
A1: for x be set holds x is Element of l1 iff x is Complex_Sequence & seq_id
  x is bounded
  proof
    let x be set;
    x in the_set_of_ComplexSequences iff x is Complex_Sequence by FUNCT_2:8,66;
    hence thesis by Def1;
  end;
A2: for u,v be VECTOR of l1 holds u+v =seq_id u+seq_id v
  proof
    let u,v be VECTOR of l1;
    reconsider u1=u, v1 = v as VECTOR of Linear_Space_of_ComplexSequences by
Lm5,CLVECT_1:29;
    set L1=Linear_Space_of_ComplexSequences;
    set W = the_set_of_BoundedComplexSequences;
    dom (the addF of L1) = [:the carrier of L1,the carrier of L1:] by
FUNCT_2:def 1;
    then
A3: dom ((the addF of Linear_Space_of_ComplexSequences)||W) =[:W,W:] by
RELAT_1:62;
    u+v =((the addF of Linear_Space_of_ComplexSequences)||W).[u,v] by
CSSPACE:def 8
      .=u1+v1 by A3,FUNCT_1:47;
    hence thesis by CSSPACE:2;
  end;
A4: for c be Complex, u be VECTOR of l1 holds c*u =c(#)seq_id u
  proof
    let c be Complex;
    let u be VECTOR of l1;
    reconsider u1=u as VECTOR of Linear_Space_of_ComplexSequences by Lm5,
CLVECT_1:29;
    set L1=Linear_Space_of_ComplexSequences;
    set W = the_set_of_BoundedComplexSequences;
    reconsider c as Element of COMPLEX by XCMPLX_0:def 2;
    dom (the Mult of L1) = [:COMPLEX,the carrier of L1:] by FUNCT_2:def 1;
    then
A5: dom ((the Mult of Linear_Space_of_ComplexSequences) | [:COMPLEX,W :])
    =[:COMPLEX,W:] by RELAT_1:62,ZFMISC_1:96;
    c*u =(the Mult of l1).[c,u] by CLVECT_1:def 1
      .=((the Mult of Linear_Space_of_ComplexSequences)|[:COMPLEX,W:]).[c,u]
    by CSSPACE:def 9
      .=(the Mult of Linear_Space_of_ComplexSequences).[c,u] by A5,FUNCT_1:47
      .=c*u1 by CLVECT_1:def 1;
    hence thesis by CSSPACE:3;
  end;
A6: for u be VECTOR of l1 holds u = seq_id u
  proof
    let u be VECTOR of l1;
    u is VECTOR of Linear_Space_of_ComplexSequences by Lm5,CLVECT_1:29;
    hence thesis;
  end;
A7: for u be VECTOR of l1 holds -u =-seq_id u & seq_id(-u)=-seq_id u
  proof
    let u be VECTOR of l1;
    -u = (-1r)*u by CLVECT_1:3
      .= (-1r)(#)seq_id u by A4
      .= -seq_id u by COMSEQ_1:11;
    hence thesis;
  end;
A8: for u,v be VECTOR of l1 holds u-v =seq_id u-seq_id v
  proof
    let u,v be VECTOR of l1;
    thus u-v = seq_id u+seq_id(-v) by A2
      .= seq_id u-seq_id v by A7;
  end;
A9: for v be VECTOR of l1 holds ||.v.|| = upper_bound rng |.seq_id v.|
     by Def2;
  0.l1 = 0.Linear_Space_of_ComplexSequences by CSSPACE:def 10
    .= CZeroseq;
  hence thesis by A1,A6,A2,A4,A7,A8,A9;
end;
