reserve p,p1,p2,q1,q2 for Point of TOP-REAL 2,
  P1,P2 for Subset of TOP-REAL 2,
  f,f1,f2,g1,g2 for FinSequence of TOP-REAL 2,
  n,m,i,j,k for Nat,
  G,G1 for Go-board,
  x,y for set;

theorem Th2:
  for G,f1,f2 st 2<=len f1 & 2<=len f2 & f1 is_sequence_on G & f2
  is_sequence_on G & f1/.1 in rng Line(G,1) & f1/.len f1 in rng Line(G,len G) &
f2/.1 in rng Col(G,1) & f2/.len f2 in rng Col(G,width G) holds L~f1 meets L~f2
proof
  let G,f1,f2;
  assume that
A1: 2<=len f1 and
A2: 2<=len f2 and
A3: f1 is_sequence_on G & f2 is_sequence_on G & f1/.1 in rng Line(G,1) &
  f1/. len f1 in rng Line(G,len G) & f2/.1 in rng Col(G,1) & f2/.len f2 in rng
  Col( G,width G);
  1<=len f1 & 1<=len f2 by A1,A2,XXREAL_0:2;
  then rng f1 meets rng f2 by A3,Th1;
  then consider x being object such that
A4: x in rng f1 and
A5: x in rng f2 by XBOOLE_0:3;
  ex m being Element of NAT st m in dom f2 & f2/.m=x by A5,PARTFUN2:2;
  then
A6: x in L~f2 by A2,GOBOARD1:1;
  ex n being Element of NAT st n in dom f1 & f1/.n=x by A4,PARTFUN2:2;
  then x in L~f1 by A1,GOBOARD1:1;
  hence thesis by A6,XBOOLE_0:3;
end;
