reserve i, I for set,
  f, g, h for Function,
  s for ManySortedSet of I;

theorem
  for F being multMagma-Family of I, G being non empty multMagma st
  i in I & G = F.i & product F is Group-like holds G is Group-like
proof
  let F be multMagma-Family of I, G be non empty multMagma such that
A1: i in I and
A2: G = F.i;
  set GP = product F;
  given e being Element of GP such that
A3: for h being Element of GP holds h * e = h & e * h = h & ex g being
  Element of GP st h * g = e & g * h = e;
  reconsider f = e as Element of product Carrier F by Def2;
  reconsider ei = f.i as Element of G by A1,A2,Lm1;
  take ei;
  let h be Element of G;
  defpred P[object,object] means
($1 = i implies $2 = h) & ($1 <> i implies ex H
  being non empty multMagma, a being Element of H st H = F.$1 & $2 = a);
A4: for j being object st j in I ex k being object st P[j,k]
  proof
    let j be object such that
A5: j in I;
    per cases;
    suppose
      j = i;
      hence thesis;
    end;
    suppose
A6:   j <> i;
      j in dom F by A5,PARTFUN1:def 2;
      then F.j in rng F by FUNCT_1:def 3;
      then reconsider Fj = F.j as non empty multMagma by Def1;
      set a = the Element of Fj;
      take a;
      thus j = i implies a = h by A6;
      thus thesis;
    end;
  end;
  consider g being ManySortedSet of I such that
A7: for j being object st j in I holds P[j,g.j] from PBOOLE:sch 3(A4);
A8: dom g = I by PARTFUN1:def 2;
A9: now
    let j be object;
    assume
A10: j in dom g;
    then
A11: ex R being 1-sorted st R = F.j & (Carrier F).j = the carrier of R
    by PRALG_1:def 15;
    per cases;
    suppose
A12:  i = j;
      then g.j = h by A7,A10;
      hence g.j in (Carrier F).j by A2,A11,A12;
    end;
    suppose
      j <> i;
      then ex H being non empty multMagma, a being Element of H st H = F.j &
      g.j = a by A7,A10;
      hence g.j in (Carrier F).j by A11;
    end;
  end;
  dom Carrier F = I by PARTFUN1:def 2;
  then reconsider g as Element of product Carrier F by A8,A9,CARD_3:9;
A13: g.i = h by A1,A7;
  reconsider g1 = g as Element of GP by Def2;
A14: e * g1 = g1 by A3;
  g1 * e = g1 by A3;
  hence h * ei = h & ei * h = h by A1,A2,A13,A14,Th1;
  consider gg being Element of GP such that
A15: g1 * gg = e and
A16: gg * g1 = e by A3;
  reconsider r = gg as Element of product Carrier F by Def2;
  reconsider r1 = r.i as Element of G by A1,A2,Lm1;
  take r1;
  thus thesis by A1,A2,A13,A15,A16,Th1;
end;
