reserve i,j,k,n,m for Nat,
        b,b1,b2 for bag of n;

theorem Th2:
  for X being set, f being X-defined Function,
    perm being Permutation of X holds
  card support (f*perm) = card support (f)
proof
  let X be set,
    f be X-defined Function,
    perm be Permutation of X;
    set P=perm";
A1:dom perm=X=rng perm & dom P=X=rng P by FUNCT_2:52,def 3;
  support (f) c= dom f c= X = dom P by FUNCT_2:52,PRE_POLY:37;
  then
A2: support (f) c= dom P;
A3:P.:support (f) c= support (f*perm)
  proof
    let y be object;assume y in P.:support (f);
    then consider x be object such that
A4:x in dom P & x in support f & P.x=y by FUNCT_1:def 6;
A5:x = perm.y by A1,A4,FUNCT_1:32;
A6:f.x <>0 by A4,PRE_POLY:def 7;
    then x in dom f & y in dom perm by A4,A1,FUNCT_1:def 2,def 3;
    then perm.y in dom f & f.(perm.y) = (f*perm).y
      by A1,A4,FUNCT_1:32,FUNCT_1:13;
    hence thesis by A6,A5,PRE_POLY:def 7;
  end;
  support (f*perm) c= P.:support (f)
  proof
    let y be object;assume y in support (f*perm);
    then A7:(f*perm).y <>0 by PRE_POLY:def 7;
    then y in dom (f*perm) by FUNCT_1:def 2;
    then f.(perm.y) = (f*perm).y & y in dom perm & perm.y in dom f
    by FUNCT_1:11,12;
    then perm.y in dom P & perm.y in support (f) & P.(perm.y)=y
    by A1,A7,FUNCT_1:32,PRE_POLY:def 7;
    hence thesis by FUNCT_1:def 6;
  end;
  then support (f*perm) = P.:support (f) by A3,XBOOLE_0:def 10;
  hence thesis by CARD_1:5,A2,CARD_1:33;
end;
