reserve i,j,n,n1,n2,m,k,l,u for Nat,
        i1,i2,i3,i4,i5,i6 for Element of n,
        p,q for n-element XFinSequence of NAT,
        a,b,c,d,e,f for Integer;

theorem Th2:
   m >= n > 0 implies
     1+(m! * idseq n) is CR_Sequence
proof
  assume
A1: m >= n > 0;
  set h=1+(m! * idseq n);
  deffunc F(Nat)=(m!)*$1+1;
A2: len h = n by CARD_1:def 7;
A3: for i st i in dom h holds h.i = F(i)
  proof
    let i such that
A4: i in dom h;
A5: dom h = dom (m! * idseq n) =dom idseq n by VALUED_1:def 2,def 5;
    thus h.i = 1 + (m! * idseq n).i by A4,VALUED_1:def 2
    .= 1+(m! * ((idseq n).i)) by A4,A5,VALUED_1:def 5
    .= F(i) by A4,A5,FINSEQ_2:49;
  end;
A6: h is positive-yielding
  proof
    let r be Real;
    assume r in rng h;
    then consider x be object such that
A7: x in dom h & h.x=r by FUNCT_1:def 3;
    reconsider x as Nat by A7;
    F(x)>0;
    hence thesis by A7,A3;
  end;
  reconsider h as non empty positive-yielding INT -valued FinSequence
    by A1,A6;
A8: for i,j being Nat st i in dom h & j in dom h & i < j holds
    h.i, h.j are_coprime
  proof
    let i,j be Nat such that
A9: i in dom h & j in dom h & i < j;
    reconsider ji=j-i as Nat by A9,NAT_1:21;
    set G=h.i gcd h.j;
A10:h.i = F(i) & h.j = F(j) by A9,A3;
    then
A11: G >=1 by NAT_1:14;
    assume not h.i, h.j are_coprime;
    then G > 1 by A11,XXREAL_0:1,INT_2:def 3;
    then G is non trivial by NEWTON03:def 1;
    then consider g be Prime such that
A12:  g divides G by NEWTON03:29;
A13:  ji <>0 by A9;
    0<=i & j <=n by A9,A2,FINSEQ_3:25;
    then ji <= n-0 by XREAL_1:13;
    then
A14:  ji divides m! by A13,NEWTON:41,A1,XXREAL_0:2;
A15:  G divides F(i) & G divides F(j) by A10,INT_2:def 2;
    then
A16:  G divides F(j)-F(i) by INT_5:1;
A17:  g divides F(i) by A15,A12,INT_2:9;
    g divides m!*ji by A12,A16,INT_2:9;
    then g divides m! or g divides j-i by INT_5:7;
    then g divides m! by A14,INT_2:9;
    then g divides i*(m!) by INT_2:2;
    then g divides F(i)-i*(m!) by A17,INT_5:1;
    then g=1 or g=-1 by INT_2:13;
    hence thesis by INT_2:def 4;
  end;
  h is Chinese_Remainder
  proof
    let i,j be Nat such that A18: i in dom h & j in dom h & i <> j;
    i >j or j >i by A18,XXREAL_0:1;
    hence thesis by A18,A8;
  end;
  hence thesis;
end;
