reserve AFP for AffinPlane;
reserve a,a9,b,b9,c,c9,d,d9,o,p,p9,q,q9,r,s,t,x,y,z for Element of AFP;
reserve A,A9,C,D,P,B9,M,N,K for Subset of AFP;
reserve f for Permutation of the carrier of AFP;

theorem Th2:
  (for o,a,b st o<>a & o<>b & LIN o,a,b ex f st f is dilatation & f
  .o=o & f.a=b) implies AFP is Desarguesian
proof
  assume
A1: for o,a,b st o<>a & o<>b & LIN o,a,b ex f st f is dilatation & f.o=o
  & f.a=b;
  now
    let o,a,a9,p,p9,q,q9;
    assume that
A2: LIN o,a,a9 and
A3: LIN o,p,p9 and
A4: LIN o,q,q9 and
A5: not LIN o,a,p and
A6: not LIN o,a,q and
A7: a,p // a9,p9 and
A8: a,q // a9,q9;
A9: now
      assume
A10:  o<>a9;
      o<>a by A5,AFF_1:7;
      then consider f such that
A11:  f is dilatation and
A12:  f.o=o and
A13:  f.a=a9 by A1,A2,A10;
      set s=f.q;
      o,q // o,s by A11,A12,TRANSGEO:68;
      then
A14:  LIN o,q,s by AFF_1:def 1;
      set r=f.p;
      o,p // o,r by A11,A12,TRANSGEO:68;
      then
A15:  LIN o,p,r by AFF_1:def 1;
      a,q // a9,s by A11,A13,TRANSGEO:68;
      then
A16:  s=q9 by A2,A4,A6,A8,A14,AFF_1:56;
      a,p // a9,r by A11,A13,TRANSGEO:68;
      then r=p9 by A2,A3,A5,A7,A15,AFF_1:56;
      hence p,q // p9,q9 by A11,A16,TRANSGEO:68;
    end;
    now
      assume
A17:  o=a9;
      then o=p9 by A3,A5,A7,AFF_1:55;
      then p9=q9 by A4,A6,A8,A17,AFF_1:55;
      hence p,q // p9,q9 by AFF_1:3;
    end;
    hence p,q // p9,q9 by A9;
  end;
  hence thesis by Lm1;
end;
