 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem Th2:
  Z c= dom (cosec*exp_R) implies -cosec*exp_R is_differentiable_on Z &
  for x st x in Z holds ((-cosec*exp_R)`|Z).x
  = exp_R.x*cos.(exp_R.x)/(sin.(exp_R.x))^2
proof
  assume
A1:Z c= dom (cosec*exp_R);
then A2:Z c= dom (-cosec*exp_R) by VALUED_1:8;
A3:cosec*exp_R is_differentiable_on Z by A1,FDIFF_9:13;
then A4:(-1)(#)(cosec*exp_R) is_differentiable_on Z by A2,FDIFF_1:20;
 for x st x in Z holds ((-cosec*exp_R)`|Z).x
  = exp_R.x*cos.(exp_R.x)/(sin.(exp_R.x))^2
  proof
    let x;
    assume
A5:x in Z;
 ((-cosec*exp_R)`|Z).x=((-1)(#)((cosec*exp_R)`|Z)).x by A3,FDIFF_2:19
                 .=(-1)*(((cosec*exp_R)`|Z).x) by VALUED_1:6
                 .=(-1)*(-exp_R.x*cos.(exp_R.x)/(sin.(exp_R.x))^2)
    by A1,A5,FDIFF_9:13
                 .=exp_R.x*cos.(exp_R.x)/(sin.(exp_R.x))^2;
    hence thesis;
   end;
   hence thesis by A4;
end;
