
theorem
  for n,m be Nat, a be Function of [:Seg n,Seg m:],REAL
  for p,q be FinSequence of REAL st
    ( dom p = Seg n
    & for i be Nat st i in dom p holds
        ex r be FinSequence of REAL st
          (dom r = Seg m & p.i = Sum r
         & for j be Nat st j in dom r holds r.j=a.(i,j) ) )
  & ( dom q = Seg m
    & for j be Nat st j in dom q holds
        ex s be FinSequence of REAL st
          (dom s = Seg n & q.j = Sum s
         & for i be Nat st i in dom s holds s.i=a.(i,j) ) )
  holds Sum p = Sum q
proof
  let n,m be Nat, a be Function of [:Seg n,Seg m:],REAL;
  let p,q be FinSequence of REAL;
  assume that
A1: dom p = Seg n and
A2: for i be Nat st i in dom p holds
      ex r be FinSequence of REAL st
        ( dom r = Seg m & p.i = Sum r
        & for j be Nat st j in dom r holds r.j=a.(i,j) ) and
A3: dom q = Seg m and
A4: for j be Nat st j in dom q holds
      ex s be FinSequence of REAL st
        ( dom s = Seg n & q.j = Sum s
        & for i be Nat st i in dom s holds s.i=a.(i,j));
A5: for i be Nat st i in dom p holds
      ex r be FinSequence of REAL st
        dom r = Seg m & p.i = Sum r
      & for j be Nat st j in dom r holds r.j=a.([i,j])
  proof
    let i be Nat;
    assume B0: i in dom p;
    consider r be FinSequence of REAL such that
B2:   dom r = Seg m & p.i = Sum r
    & for j be Nat st j in dom r holds r.j=a.(i,j) by B0,A2;
B3: for j be Nat st j in dom r holds r.j=a.([i,j])
    proof
      let j be Nat;
      assume j in dom r; then
      r.j=a.(i,j) by B2;
      hence r.j=a.([i,j]);
    end;
    take r;
    thus thesis by B2,B3;
  end;
  for j be Nat st j in dom q holds
    ex s be FinSequence of REAL st
      dom s = Seg n & q.j = Sum s
    & for i be Nat st i in dom s holds s.i=a.([i,j])
  proof
    let j be Nat;
    assume C0: j in dom q;
    consider s be FinSequence of REAL such that
C2:   dom s = Seg n & q.j = Sum s
    & for i be Nat st i in dom s holds s.i=a.(i,j) by C0,A4;
C3: for i be Nat st i in dom s holds s.i=a.([i,j])
    proof
      let i be Nat;
      assume i in dom s; then
      s.i=a.(i,j) by C2;
      hence s.i=a.([i,j]);
    end;
    take s;
    thus thesis by C2,C3;
  end;
  hence Sum p = Sum q by MESFUNC3:1,A1,A5,A3;
end;
