
theorem Th2:
  for xseq, yseq be FinSequence of REAL st len xseq = len yseq
   & (for i be Element of NAT st i in dom xseq holds
      ex v be Real st v = xseq.i & yseq.i = |.v.|)
  holds |.Sum xseq.| <= Sum yseq
  proof
    defpred P[Nat] means
    for xseq, yseq be FinSequence of REAL
    st $1 = len xseq
     & len xseq = len yseq
     & (for i be Element of NAT st i in dom xseq holds
        ex v be Real st v = xseq.i & yseq.i = |.v.|)
    holds |.Sum xseq.| <= Sum yseq;
    A1: P[0]
    proof
      let xseq be FinSequence of REAL, yseq be FinSequence of REAL;
      assume
      A2: 0 = len xseq & len xseq = len yseq &
         (for i be Element of NAT st i in dom xseq holds
          ex v be Real st v = xseq.i & yseq.i = |.v.|); then
      <*>(REAL) = xseq; then
      Sum xseq = 0 & <*>(REAL) = yseq by A2,RVSUM_1:72;
      hence thesis by COMPLEX1:44,RVSUM_1:72;
    end;
    A3: now
      let i be Nat;
      assume
      A4: P[i];
      now
        let xseq be FinSequence of REAL, yseq be FinSequence of REAL;
        set xseq0 = xseq|i, yseq0 = yseq|i;
        assume
        A5: i+1=len xseq & len xseq = len yseq &
            for i be Element of NAT st i in dom xseq holds
            ex v be Real st v=xseq.i & yseq.i=|.v.|;
        A6: for k be Element of NAT st k in dom xseq0 holds
            ex v be Real st v=xseq0.k & yseq0.k=|.v.|
        proof
          let k be Element of NAT;
          assume k in dom xseq0; then
          A8: k in Seg i & k in dom xseq by RELAT_1:57; then
          consider v be Real such that
          A9: v=xseq.k & yseq.k=|.v.| by A5;
          take v;
          thus thesis by A8,A9,FUNCT_1:49;
        end;
        dom xseq = Seg(i+1) by A5,FINSEQ_1:def 3; then
        consider w be Real such that
        A10: w=xseq.(i+1) & yseq.(i+1)=|.w.| by A5,FINSEQ_1:4;
        A11: 1 <= i + 1 & i + 1 <= len yseq by A5,NAT_1:11;
        yseq = (yseq|i)^<*yseq/.(i+1) *> by A5,FINSEQ_5:21; then
        yseq = yseq0 ^<*(yseq.(i+1))*> by A11,FINSEQ_4:15; then
        A12: Sum yseq = Sum yseq0 + yseq.(i+1) by RVSUM_1:74;
        A13: i=len xseq0 by A5,FINSEQ_1:59,NAT_1:11; then
        A14: ex v be Real st v=xseq.(len xseq)
           & Sum xseq = Sum xseq0 + v by A5,Lm1;
        A15: |. Sum xseq0 + w.|<= |.Sum xseq0 .| + |. w .| by COMPLEX1:56;
        len xseq0 = len yseq0 by A5,A13,FINSEQ_1:59,NAT_1:11; then
        |. Sum xseq0 .| + |. w .| <= Sum yseq0 + yseq.(i+1)
          by A4,A6,A10,A13,XREAL_1:6;
        hence |. Sum xseq .| <= Sum yseq by A5,A10,A12,A14,A15,XXREAL_0:2;
      end;
      hence P[i+1];
    end;
    for i be Nat holds P[i] from NAT_1:sch 2(A1,A3);
    hence thesis;
  end;
