
theorem Th2:
for seq be Real_Sequence st seq is divergent_to+infty
 holds not seq is divergent_to-infty & not seq is convergent
proof
    let seq be Real_Sequence;
    assume A1: seq is divergent_to+infty;
    hereby assume seq is divergent_to-infty; then
     consider n1 be Nat such that
A2:   for m be Nat st n1<=m holds seq.m < 0 by LIMFUNC1:def 5;
     consider n2 be Nat such that
A3:   for m be Nat st n2<=m holds seq.m > 0 by A1,LIMFUNC1:def 4;
     reconsider m = max(n1,n2) as Element of NAT by ORDINAL1:def 12;
     seq.m < 0 & seq.m > 0 by A2,A3,XXREAL_0:25;
     hence contradiction;
    end;
    assume seq is convergent; then
    consider g be Real such that
A4:  for p be Real st 0<p ex n be Nat st for m be Nat st n<=m holds
      |.seq.m-g.| < p by SEQ_2:def 6;

    per cases;
    suppose g > 0; then
     consider n1 be Nat such that
A5:   for m be Nat st n1 <= m holds |.seq.m- g.| < g by A4;
A6:  now
      let m be Nat;
      assume n1 <= m; then
A7:   |.seq.m- g.| <  g by A5;
      seq.m-g <= |.seq.m-g.| by ABSVALUE:4; then
      seq.m-g < g by A7,XXREAL_0:2;
      then seq.m < g+g by XREAL_1:19;
      hence seq.m < (2*g);
     end;
     consider n2 be Nat such that
A8:   for m be Nat st n2 <= m holds (2*g) < seq.m by A1,LIMFUNC1:def 4;
     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
     seq.m < (2*g) by A6,XXREAL_0:25;
     hence contradiction by A8,XXREAL_0:25;
    end;
    suppose g < 0; then
     consider n1 be Nat such that
A9:  for m be Nat st n1 <= m holds |.seq.m- g.| <  -g by A4,XREAL_1:58;
A10: now
      let m be Element of NAT;
      assume n1 <= m; then
A11:   |.seq.m- g.| <  -g by A9;
      seq.m - g <= |.seq.m-g.| by ABSVALUE:4; then
      seq.m -  g < -g by A11,XXREAL_0:2;
      then seq.m < g-g by XREAL_1:19;
      hence seq.m < 0;
     end;
     consider n2 be Nat such that
A12:  for m be Nat st n2 <= m holds 0 < seq.m by A1,LIMFUNC1:def 4;

     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
     seq.m < 0 by A10,XXREAL_0:25;
     hence contradiction by A12,XXREAL_0:25;
    end;
    suppose A13: g = 0;
     consider n1 be Nat such that
A14:  for m be Nat st n1 <= m holds |. seq.m- g .| <  1 by A4;
     consider n2 be Nat such that
A15:  for m be Nat st n2 <= m holds  1 < seq.m by A1,LIMFUNC1:def 4;
     reconsider n1,n2 as Element of NAT by ORDINAL1:def 12;
     reconsider m = max(n1,n2) as Element of NAT;
A16: |. seq.m- g .| <  1 by A14,XXREAL_0:25;
     seq.m - g <= |.seq.m-g.| by ABSVALUE:4;
     then seq.m -  g <  1 by A16,XXREAL_0:2;
     hence contradiction by A13,A15,XXREAL_0:25;
    end;
end;
