reserve a,b,e,r,x,y for Real,
  i,j,k,n,m for Element of NAT,
  x1 for set,
  p,q for FinSequence of REAL,
  A for non empty closed_interval Subset of REAL,
  D,D1,D2 for Division of A,
  f,g for Function of A,REAL,
  T for DivSequence of A;

theorem Th2:
  vol(A) <> 0 implies ex i st i in dom D & vol(divset(D,i)) > 0
proof
  assume
A1: vol(A) <>0;
A2: len D in dom D by FINSEQ_5:6;
  assume
A3: for i st i in dom D holds vol(divset(D,i))<=0;
A4: i in dom D implies vol(divset(D,i))=0
  proof
    assume i in dom D;
    then vol(divset(D,i)) <= 0 by A3;
    hence thesis by INTEGRA1:9;
  end;
A5: i in dom D implies upper_bound divset(D,i)=lower_bound divset(D,i)
  proof
    assume i in dom D;
    then vol(divset(D,i))=0 by A4;
    then upper_bound divset(D,i)-lower_bound divset(D,i)=0 by INTEGRA1:def 5;
    hence thesis;
  end;
A6: len D = 1
  proof
    len D < len D+1 by NAT_1:13;
    then
A7: len D-1 < len D by XREAL_1:19;
    assume
A8: len D <> 1;
    then
A9: upper_bound divset(D,len D)=D.(len D) by A2,INTEGRA1:def 4;
A10: len D-1 in dom D by A2,A8,INTEGRA1:7;
    lower_bound divset(D,len D)=D.(len D-1) by A2,A8,INTEGRA1:def 4;
    then lower_bound divset(D,len D)<upper_bound divset(D,len D) by A2,A9,A10
,A7,SEQM_3:def 1;
    hence contradiction by A5,A2;
  end;
  then upper_bound divset(D,len D)=D.(len D) by A2,INTEGRA1:def 4;
  then
A11: upper_bound divset(D,len D)=upper_bound A by INTEGRA1:def 2;
  lower_bound divset(D,len D)=lower_bound A by A2,A6,INTEGRA1:def 4;
  then upper_bound A = lower_bound A+0 by A5,A2,A11;
  then upper_bound A- lower_bound A = 0;
  hence contradiction by A1,INTEGRA1:def 5;
end;
