reserve n for Nat;

theorem Th2:
  for E be compact non vertical non horizontal Subset of TOP-REAL 2
  for m,j be Nat
  st 1 <= m & m <= n & 1 <= j & j <= width Gauge(E,n) holds
  LSeg(Gauge(E,n)*(Center Gauge(E,n),width Gauge(E,n)),
  Gauge(E,n)*(Center Gauge(E,n),j)) c=
  LSeg(Gauge(E,m)*(Center Gauge(E,m),width Gauge(E,m)),
  Gauge(E,n)*(Center Gauge(E,n),j))
proof
  let E be compact non vertical non horizontal Subset of TOP-REAL 2;
  let m,j be Nat;
  set a = N-bound E, s = S-bound E, w = W-bound E, e = E-bound E,
  G = Gauge(E,n), M = Gauge(E,m), sn = Center G, sm = Center M;
  assume that
A1: 1 <= m and
A2: m <= n and
A3: 1 <= j and
A4: j <= width G;
A5: width M = len M by JORDAN8:def 1
    .= 2|^m+3 by JORDAN8:def 1;
A6: width G = len G by JORDAN8:def 1
    .= 2|^n+3 by JORDAN8:def 1;
A7: now
    let t be Nat;
    assume that
A8: width G >= t and
A9: t >= j;
A10: len M = width M by JORDAN8:def 1;
A11: len G = width G by JORDAN8:def 1;
A12: 0 < a - s by SPRECT_1:32,XREAL_1:50;
A13: t >= 1 by A3,A9,XXREAL_0:2;
A14: 0 < 2|^m by NEWTON:83;
A15: 1 <= len M by GOBRD11:34;
    then
A16: M*(sm,width M)`1 = G*(sn,t)`1 by A1,A2,A8,A10,A11,A13,JORDAN1A:36;
A17: G*(sn,t)`1 = G*(sn,j)`1 by A1,A2,A3,A4,A8,A11,A13,JORDAN1A:36;
    [sn,t] in Indices G by A8,A13,Lm1;
    then
A18: G*(sn,t)`2 = |[w+(e-w)/(2|^n)*(sn - 2),s+(a-s)/(2|^n)*(t-2)]|`2
    by JORDAN8:def 1
      .= s+(a-s)/(2|^n)*(t-2);
    [sm,width M] in Indices M by A10,A15,Lm1;
    then
A19: M*(sm,width M)`2 = s+(a-s)/(2|^m)*(width M-2) by Lm2;
A20: (2|^m+1)/(2|^m) >= (2|^n+1)/(2|^n) by A2,A14,Th1,PREPOWER:93;
    t-2 <= 2|^n+3-2 by A6,A8,XREAL_1:9;
    then (t-2)/(2|^n) <= (2|^n+1)/(2|^n) by XREAL_1:72;
    then (t-2)/(2|^n) <= (width M-2)/(2|^m) by A5,A20,XXREAL_0:2;
    then (a-s)*((t-2)/(2|^n)) <= (a-s)*((width M-2)/(2|^m)) by A12,XREAL_1:64;
    then
A21: s+(a-s)/(2|^m)*(width M-2) >= s+(a-s)/(2|^n)*(t-2) by XREAL_1:6;
A22: 1 <= sn by JORDAN1B:11;
    sn <= len G by JORDAN1B:13;
    then G*(sn,t)`2 >= G*(sn,j)`2 by A3,A8,A9,A22,SPRECT_3:12;
    hence G*(sn,t) in LSeg(M*(sm,width M),G*(sn,j)) by A16,A17,A18,A19,A21,
GOBOARD7:7;
  end;
  then
A23: G*(sn,width G) in LSeg(M*(sm,width M),G*(sn,j)) by A4;
  G*(sn,j) in LSeg(M*(sm,width M),G*(sn,j)) by A4,A7;
  hence thesis by A23,TOPREAL1:6;
end;
