
theorem
  for L being Lattice,
      I being Ideal of L holds
    I is prime iff
      I` is Filter of L or I` = {}
  proof
    let L be Lattice,
        I be Ideal of L;
    set F = I`;
    thus I is prime implies I` is Filter of L or I` = {}
    proof
      assume I is prime; then
  A1: for x,y being Element of L st x "/\" y in I holds x in I or y in I
        by FILTER_2:def 10;
  A2: F is meet-closed
      proof
        let x,y be Element of L;
        assume x in F & y in F;
        then (not x in I) & not y in I by XBOOLE_0:def 5;
        hence thesis by A1,SUBSET_1:29;
      end;
      F is final
      proof
        let x,y be Element of L;
        assume that
  A5:   x [= y and
  A4:   x in F;
        y in I implies x in I by A5,LATTICES:def 22;
        hence thesis by A4,XBOOLE_0:def 5;
      end;
      hence thesis by A2;
    end;
    assume
A6: I` is Filter of L or I` = {};
    for x, y being Element of L holds
      x "/\" y in I iff x in I or y in I
    proof
      let x,y be Element of L;
      hereby
        assume x "/\" y in I; then
  T1:   not x "/\" y in F by XBOOLE_0:def 5;
        per cases by A6;
        suppose F is Filter of L; then
          not x in F or not y in F by T1,FILTER_0:9;
          hence x in I or y in I by XBOOLE_0:def 5;
        end;
        suppose
      T2: F = {};
          I = F`;
          hence x in I or y in I by T2;
        end;
      end;
      assume x in I or y in I; then
  T4: not x in F or not y in F by XBOOLE_0:def 5;
      per cases by A6;
      suppose F is Filter of L; then
        not x "/\" y in F by FILTER_0:8,T4;
        hence x "/\" y in I by XBOOLE_0:def 5;
      end;
      suppose
    T2: F = {};
        I = F`;
        hence x "/\" y in I by T2;
      end;
    end;
    hence thesis by FILTER_2:def 10;
  end;
