reserve x,y for object,X,Y for set,
  D for non empty set,
  i,j,k,l,m,n,m9,n9 for Nat,
  i0,j0,n0,m0 for non zero Nat,
  K for Field,
  a,b for Element of K,
  p for FinSequence of K,
  M for Matrix of n,K;

theorem Th2:
  M is lower_triangular Matrix of n,K iff M@ is upper_triangular Matrix of n,K
proof
  thus M is lower_triangular Matrix of n,K implies M@ is
  upper_triangular Matrix of n,K
  proof
    assume
A1: M is lower_triangular Matrix of n,K;
    now
      let i,j such that
A2:   [i,j] in Indices M@ and
A3:   i>j;
A4:   [j,i] in Indices M by A2,MATRIX_0:def 6;
      then M*(j,i)=0.K by A1,A3,MATRIX_1:def 9;
      hence M@*(i,j) = 0.K by A4,MATRIX_0:def 6;
    end;
    hence thesis by MATRIX_1:def 8;
  end;
  assume
A5: M@ is upper_triangular Matrix of n,K;
  now
    let i,j such that
A6: [i,j] in Indices M and
A7: i<j;
    [j,i] in Indices M@ by A6,MATRIX_0:def 6;
    then M@*(j,i)=0.K by A5,A7,MATRIX_1:def 8;
    hence M*(i,j) = 0.K by A6,MATRIX_0:def 6;
  end;
  hence thesis by MATRIX_1:def 9;
end;
