reserve i,j,n for Nat,
  K for Field,
  a for Element of K,
  M,M1,M2,M3,M4 for Matrix of n,K;
reserve A for Matrix of K;

theorem Th2:
  for K being Ring,A being Matrix of K holds
    A*(0.(K,width A,width A))=0.(K,len A,width A)
proof
  let K be Ring,A be Matrix of K;
A1: width -(A*(0.(K,width A,width A)))=width (A*(0.(K,width A,width A))) by
MATRIX_3:def 2;
  set B= A*(0.(K,width A,width A));
  per cases by NAT_1:3;
  suppose
A2: width A > 0;
A3: len (0.(K,width A,width A))=width A by MATRIX_0:def 2;
    then
A4: len (A*(0.(K,width A,width A)))=len A by MATRIX_3:def 4;
A5: width (0.(K,width A,width A))=width A by A2,A3,MATRIX_0:20;
    then
A6: width (A*(0.(K,width A,width A)))=width A by A3,MATRIX_3:def 4;
    A*(0.(K,width A,width A)) =A*(0.(K,width A,width A)+0.(K,width A,width A
    )) by MATRIX_3:4
      .= A*(0.(K,width A,width A))+A*(0.(K,width A,width A)) by A3,A5
,MATRIX_4:62;
    then
    len -(A*(0.(K,width A,width A)))=len (A*(0.(K,width A,width A))) & 0.(K,
    len A,width A)=B+B+(-B) by A4,A6,MATRIX_3:def 2,MATRIX_4:2;
    then 0.(K,len A,width A)=B+(B-B) by A1,MATRIX_3:3
      .=A*(0.(K,width A,width A)) by A4,A1,MATRIX_4:20;
    hence thesis;
  end;
  suppose
A7: width A = 0;
    set LHS = A*(0.(K,width A,width A));
    set RHS = (0.(K,len A,width A));
    per cases by NAT_1:3;
    suppose
A8:   len A = 0;
      A9: len (0.(K,width A,width A)) = 0 by A7,MATRIX_0:22;
      A10: width (0.(K,width A,width A)) = 0 by A7,MATRIX_0:22;
      A11: len LHS = len A & width LHS = width (0.(K,width A,width A))
      by A7,A9,MATRIX_3:def 4;
      then width LHS = 0 by A10;
      then Seg (width LHS) = {};
      then {} = [:(dom LHS), Seg (width LHS):] by ZFMISC_1:90
         .= Indices LHS by MATRIX_0:def 4;
      then
A12:  for i,j being Nat st [i,j] in Indices LHS
      holds LHS * (i,j) = RHS * (i,j);
      len LHS = len RHS & width LHS = width RHS
      by A8,A10,A11,MATRIX_0:22;
      hence thesis by A12,MATRIX_0:21;
    end;
    suppose
A13:   len A > 0;
A14:  width (0.(K,width A,width A)) = 0 by A7,MATRIX_0:22;
      len (0.(K, width A, width A)) = width A by A7,MATRIX_0:22;
      then
A15:    len LHS = len A & width LHS = width (0.(K,width A,width A))
      by MATRIX_3:def 4;
      Seg (width LHS) = {} by A14,A15;
      then {} = [:(dom LHS), Seg (width LHS):] by ZFMISC_1:90
         .= Indices LHS by MATRIX_0:def 4;
      then
A16:   for i,j being Nat st [i,j] in Indices LHS
       holds LHS * (i,j) = RHS * (i,j);
      len LHS = len RHS & width LHS = width RHS
      by A7,A14,A15,A13,MATRIX_0:23;
      hence thesis by A16,MATRIX_0:21;
    end;
  end;
end;
