reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem Th2:
  f is real-valued or g is real-valued implies
  dom (f+g) = dom f /\ dom g & dom (f-g) = dom f /\ dom g
proof
  assume
A1: f is real-valued or g is real-valued;
 now per cases by A1;
    suppose
A2:   f is real-valued;
then    not +infty in rng f;
then A3:   f"{+infty} = {} by FUNCT_1:72;
   not -infty in rng f by A2;
then A4:   f"{-infty} = {} by FUNCT_1:72;
then
A5:   (f"{+infty} /\ g"{-infty}) \/ (f"{-infty} /\ g"{+infty}) = {} by A3;
A6:   (f"{+infty} /\ g"{+infty}) \/ (f"{-infty} /\ g"{-infty}) = {} by A3,A4;
  dom (f+g) = (dom f /\ dom g)\{} by A5,MESFUNC1:def 3;
      hence thesis by A6,MESFUNC1:def 4;
    end;
    suppose
A7:  g is real-valued;
then   not +infty in rng g;
then A8:  g"{+infty} = {} by FUNCT_1:72;
  not -infty in rng g by A7;
then A9:  g"{-infty} = {} by FUNCT_1:72;
then
A10:  (f"{+infty} /\ g"{-infty}) \/ (f"{-infty} /\ g"{+infty}) = {} by A8;
A11:  (f"{+infty} /\ g"{+infty}) \/ (f"{-infty} /\ g"{-infty}) = {} by A8,A9;
  dom (f+g) = (dom f /\ dom g)\{} by A10,MESFUNC1:def 3;
      hence thesis by A11,MESFUNC1:def 4;
    end;
  end;
  hence thesis;
end;
