reserve a,b,c,k,m,n for Nat;
reserve i,j,x,y for Integer;
reserve p,q for Prime;
reserve r,s for Real;

theorem Th2:
  for f being positive-yielding integer-valued FinSequence holds Product f >= 1
  proof
    let f be positive-yielding integer-valued FinSequence;
    defpred P[set] means
    for F being positive-yielding integer-valued FinSequence st F = $1
    holds Product F >= 1;
A1: P[<*>INT] by RVSUM_1:94;
A2: for p being FinSequence of INT for x being Element of INT st
    P[p] holds P[p^<*x*>]
    proof
      let p be FinSequence of INT;
      let x be Element of INT such that
A3:   P[p];
      let F be positive-yielding integer-valued FinSequence such that
A4:   F = p^<*x*>;
      p is positive-yielding by A4,NUMBER08:37;
      then
A5:   Product p >= 1 by A3;
A6:   <*x*> is positive-yielding by A4,NUMBER08:37;
      x in {x} by TARSKI:def 1;
      then x in rng <*x*> by FINSEQ_1:38;
      then
A7:   x >= 0+1 by A6,INT_1:7;
      Product F = Product p * x by A4,RVSUM_1:96;
      then Product F >= 1*1 by A5,A7,XREAL_1:66;
      hence Product F >= 1;
    end;
A8: for p being FinSequence of INT holds P[p] from FINSEQ_2:sch 2(A1,A2);
    f is FinSequence of INT by FINSEQ_1:104;
    hence thesis by A8;
  end;
