reserve i for Nat;
reserve R for Relation;
reserve A for set;
reserve PT for non empty TopSpace;
reserve PM for MetrSpace;
reserve FX,GX,HX for Subset-Family of PT;
reserve Y,V,W for Subset of PT;

theorem Th2:
  PT is regular implies for FX st FX is Cover of PT & FX is open ex
HX st HX is open & HX is Cover of PT & for V st V in HX ex W st W in FX & Cl V
  c= W
proof
  assume
A1: PT is regular;
  let FX;
  assume that
A2: FX is Cover of PT and
A3: FX is open;
  defpred P[set] means ex V1 being Subset of PT st V1 = $1 & V1 is open & ex W
  st W in FX & Cl V1 c= W;
  consider HX such that
A4: for V being Subset of PT holds V in HX iff P[V] from SUBSET_1:sch 3;
  take HX;
  for V being Subset of PT st V in HX holds V is open
  proof
    let V be Subset of PT;
    assume V in HX;
    then
    ex V1 being Subset of PT st V1 = V & V1 is open & ex W st W in FX & Cl
    V1 c= W by A4;
    hence thesis;
  end;
  hence HX is open by TOPS_2:def 1;
  the carrier of PT c= union HX
  proof
    let x be object;
    assume x in the carrier of PT;
    then reconsider x as Point of PT;
    consider V being Subset of PT such that
A5: x in V and
A6: V in FX by A2,PCOMPS_1:3;
    reconsider V as Subset of PT;
    now
      per cases;
      suppose
A7:     V`<> {};
        V is open by A3,A6,TOPS_2:def 1;
        then
A8:     V` is closed;
        x in V`` by A5;
        then consider X,Y being Subset of PT such that
A9:     X is open and
A10:    Y is open and
A11:    x in X and
A12:    V` c= Y and
A13:    X misses Y by A1,A7,A8,COMPTS_1:def 2;
        X c= Y` & Y` is closed by A10,A13,SUBSET_1:23;
        then
A14:    Cl X c= Y` by TOPS_1:5;
        Y` c= V by A12,SUBSET_1:17;
        then Cl X c= V by A14;
        then X in HX by A4,A6,A9;
        hence x in union HX by A11,TARSKI:def 4;
      end;
      suppose
A15:    V` = {};
        consider X being Subset of PT such that
A16:    X=[#](PT);
A17:    X is open by A16;
        V = ({}(PT))` by A15
          .= [#](PT) by PRE_TOPC:6;
        then Cl X = V by A16,TOPS_1:2;
        then X in HX by A4,A6,A17;
        hence x in union HX by A16,TARSKI:def 4;
      end;
    end;
    hence thesis;
  end;
  hence HX is Cover of PT by SETFAM_1:def 11;
  let V be Subset of PT;
  assume V in HX;
  then ex V1 being Subset of PT st V1 = V & V1 is open & ex W st W in FX & Cl
  V1 c= W by A4;
  hence thesis;
end;
