reserve I for non empty set,
  J for ManySortedSet of I,
  S for non void non empty ManySortedSign,
  i for Element of I,
  c for set,
  A for MSAlgebra-Family of I,S,
  EqR for Equivalence_Relation of I,
  U0,U1,U2 for MSAlgebra over S,
  s for SortSymbol of S,
  o for OperSymbol of S,
  f for Function;

theorem Th2:
  for A be MSAlgebra-Family of I,S, s be SortSymbol of S, a be non
empty Subset of I, Aa be MSAlgebra-Family of a,S st A|a = Aa holds Carrier(Aa,s
  ) = (Carrier(A,s))|a
proof
  let A be MSAlgebra-Family of I,S, s be SortSymbol of S, a be non empty
  Subset of I, Aa be MSAlgebra-Family of a,S such that
A1: A|a = Aa;
  dom ((Carrier(A,s))|a) = dom (Carrier(A,s)) /\ a by RELAT_1:61
    .= I /\ a by PARTFUN1:def 2
    .= a by XBOOLE_1:28;
  then reconsider Cas = ((Carrier(A,s))|a) as ManySortedSet of a by
PARTFUN1:def 2;
  for i be object st i in a holds (Carrier(Aa,s)).i = Cas.i
  proof
    let i be object;
    assume
A2: i in a;
    then reconsider i9 = i as Element of a;
    reconsider i99 = i9 as Element of I;
A3: Aa.i9 = A.i9 & ex U1 being MSAlgebra over S st U1 = A.i99 & (Carrier(A
    ,s) ).i99 = (the Sorts of U1).s by A1,FUNCT_1:49,PRALG_2:def 9;
    ex U0 being MSAlgebra over S st U0 = Aa.i & (Carrier(Aa,s) ).i = (the
    Sorts of U0).s by A2,PRALG_2:def 9;
    hence thesis by A3,FUNCT_1:49;
  end;
  hence thesis by PBOOLE:3;
end;
