reserve Omega for set;
reserve m,n,k for Nat;
reserve x,y for object;
reserve r,r1,r2,r3 for Real;
reserve seq,seq1 for Real_Sequence;
reserve Sigma for SigmaField of Omega;
reserve ASeq,BSeq for SetSequence of Sigma;
reserve A, B, C, A1, A2, A3 for Event of Sigma;

theorem Th2:
  (seq is convergent & for n holds seq1.n = r - seq.n) implies seq1
  is convergent & lim seq1 = r - lim seq
proof
  assume that
A1: seq is convergent and
A2: for n holds seq1.n = r - seq.n;
  consider r1 be Real such that
A3: for r2 be Real st 0<r2 ex n st for m st n<=m
  holds |.seq.m-r1.|<r2 by A1,SEQ_2:def 6;
A4: now
    let r2 be Real;
    assume 0 < r2;
    then consider n such that
A5: for m st n <= m holds |.seq.m - r1.| < r2 by A3;
    take n;
    now
      let m such that
A6:   n <= m;
      |.seq.m - r1.| = |.-(seq.m - r1).| by COMPLEX1:52
        .= |.r1 - r + (r - seq.m).|
        .= |.seq1.m + - (-(r1 - r)).| by A2
        .= |.seq1.m - (r - r1).|;
      hence |.seq1.m - (r - r1).| < r2 by A5,A6;
    end;
    hence for m st n <= m holds |.seq1.m - (r - r1).| < r2;
  end;
  hence
A7: seq1 is convergent by SEQ_2:def 6;
  lim seq = r1 by A1,A3,SEQ_2:def 7;
  hence thesis by A4,A7,SEQ_2:def 7;
end;
