reserve Omega, Omega1, Omega2 for non empty set;
reserve Sigma for SigmaField of Omega;
reserve S1 for SigmaField of Omega1;
reserve S2 for SigmaField of Omega2;

theorem Th2:
  for f be Function of Omega1,Omega2,
  B be SetSequence of Omega2,
  D be SetSequence of Omega1
  st for n be Element of NAT holds D.n = f "(B.n) holds
  f"(Union B) = Union D
  proof
    let f be Function of Omega1,Omega2,
    B be SetSequence of Omega2,
    D be SetSequence of Omega1;
    assume A1: for n be Element of NAT holds D.n = f "(B.n);
    set Z = rng D;
    set Q = the set of all f "Y where Y is Element of (rng B) ;
    for x be object holds x in Z iff x in Q
    proof
      let x be object;
      hereby assume x in Z;
        then consider n be Element of NAT such that
        A2: x = D.n by FUNCT_2:113;
        A3: x = f "(B.n) by A1,A2;
        B.n in rng B by FUNCT_2:112;
        hence x in Q by A3;
      end;
      assume x in Q;
      then consider Y be Element of (rng B) such that
      A4:x =f "Y;
      consider n be Element of NAT such that
      A5: Y=B.n by FUNCT_2:113;
      x =D.n by A1,A4,A5;
      hence x in Z by FUNCT_2:112;
    end;
    then Z = Q by TARSKI:2;
    hence thesis by Th1;
  end;
