reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem
  for p1,p2,w1,w2 be Element of V st v in conv I & u in conv I &
      not u in conv(I\{p1}) & not u in conv(I\{p2}) &
      w1 in conv(I\{p1}) & w2 in conv(I\{p2}) &
      r*u+(1-r)*w1 = v & s*u + (1-s)*w2 = v & r < 1 & s < 1
    holds w1 = w2 & r = s
  proof
    let p1,p2,w1,w2 be Element of V;
    assume that
    A1: v in conv I and
    A2: u in conv I and
    A3: not u in conv(I\{p1}) and
    A4: not u in conv(I\{p2}) and
    A5: w1 in conv(I\{p1}) and
    A6: w2 in conv(I\{p2}) and
    A7: r*u+(1-r)*w1=v and
    A8: s*u+(1-s)*w2=v and
    A9: r<1 and
    A10: s<1;
    set Lu=u|--I,Lv=v|--I,Lw1=w1|--I,Lw2=w2|--I;
    A11: conv I c=Affin I by RLAFFIN1:65;
    A12: Lu.p2>0
    proof
      assume A13: Lu.p2<=0;
      Lu.p2>=0 by A2,RLAFFIN1:71;
      then for y st y in {p2} holds Lu.y=0 by A13,TARSKI:def 1;
      hence contradiction by A2,A4,RLAFFIN1:76;
    end;
    conv(I\{p2})c=Affin(I\{p2}) by RLAFFIN1:65;
    then Lw2=w2|--(I\{p2}) by A6,RLAFFIN1:77,XBOOLE_1:36;
    then Carrier Lw2 c=I\{p2} by RLVECT_2:def 6;
    then not p2 in Carrier Lw2 by ZFMISC_1:56;
    then A14: Lw2.p2=0;
    A15: Lu.p1>0
    proof
      assume A16: Lu.p1<=0;
      Lu.p1>=0 by A2,RLAFFIN1:71;
      then for y st y in {p1} holds Lu.y=0 by A16,TARSKI:def 1;
      hence contradiction by A2,A3,RLAFFIN1:76;
    end;
    conv(I\{p1})c=Affin(I\{p1}) by RLAFFIN1:65;
    then Lw1=w1|--(I\{p1}) by A5,RLAFFIN1:77,XBOOLE_1:36;
    then Carrier Lw1 c=I\{p1} by RLVECT_2:def 6;
    then not p1 in Carrier Lw1 by ZFMISC_1:56;
    then A17: Lw1.p1=0;
    A18: conv(I\{p2})c=conv I by RLAFFIN1:3,XBOOLE_1:36;
    then w2 in conv I by A6;
    then s*Lu+(1-s)*Lw2=Lv by A2,A8,A11,RLAFFIN1:70;
    then Lv.p2=(s*Lu).p2+((1-s)*Lw2).p2 by RLVECT_2:def 10
    .=s*(Lu.p2)+((1-s)*Lw2).p2 by RLVECT_2:def 11
    .=s*(Lu.p2)+(1-s)*(Lw2.p2) by RLVECT_2:def 11
    .=s*(Lu.p2) by A14;
    then A19: Lv.p2<1*Lu.p2 by A10,A12,XREAL_1:68;
    then A20: Lu.p2-Lv.p2>=Lv.p2-Lv.p2 by XREAL_1:9;
    A21: conv(I\{p1})c=conv I by RLAFFIN1:3,XBOOLE_1:36;
    then Lw1.p2>=0 by A5,RLAFFIN1:71;
    then A22: 1/(1-s)-0>=1/(1-s)-Lw1.p2/(Lu.p2-Lv.p2) by A20,XREAL_1:10;
    w1 in conv I by A5,A21;
    then Lv=r*Lu+(1-r)*Lw1 by A2,A7,A11,RLAFFIN1:70;
    then Lv.p1=(r*Lu).p1+((1-r)*Lw1).p1 by RLVECT_2:def 10
    .=r*(Lu.p1)+((1-r)*Lw1).p1 by RLVECT_2:def 11
    .=r*(Lu.p1)+(1-r)*(Lw1.p1) by RLVECT_2:def 11
    .=r*(Lu.p1) by A17;
    then A23: Lv.p1<1*Lu.p1 by A9,A15,XREAL_1:68;
    then A24: Lu.p1-Lv.p1>=Lv.p1-Lv.p1 by XREAL_1:9;
    w2=(1/(1-s)*v)+(1-1/(1-s))*u by A8,A10,Lm1;
    then A25: Lw2=1/(1-s)*Lv+(1-1/(1-s))*Lu by A1,A2,A11,RLAFFIN1:70;
    then A26: 1/(1-s)=(Lu.p2-0)/(Lu.p2-Lv.p2) by A14,A19,RLAFFIN1:81;
    A27: w1=(1/(1-r)*v)+(1-1/(1-r))*u by A7,A9,Lm1;
    then A28: Lw1=1/(1-r)*Lv+(1-1/(1-r))*Lu by A1,A2,A11,RLAFFIN1:70;
    then A29: 1/(1-r)=(Lu.p2-Lw1.p2)/(Lu.p2-Lv.p2) by A19,RLAFFIN1:81
    .=1/(1-s)-Lw1.p2/(Lu.p2-Lv.p2) by A26,XCMPLX_1:120;
    Lw2.p1>=0 by A6,A18,RLAFFIN1:71;
    then A30: 1/(1-r)-0>=1/(1-r)-Lw2.p1/(Lu.p1-Lv.p1) by A24,XREAL_1:10;
    A31: 1/(1-r)=(Lu.p1-0)/(Lu.p1-Lv.p1) by A17,A23,A28,RLAFFIN1:81;
    1/(1-s)=(Lu.p1-Lw2.p1)/(Lu.p1-Lv.p1) by A23,A25,RLAFFIN1:81
    .=1/(1-r)-Lw2.p1/(Lu.p1-Lv.p1) by A31,XCMPLX_1:120;
    then 1-r=1-s by A30,A22,A29,XCMPLX_1:59,XXREAL_0:1;
    hence thesis by A8,A10,A27,Lm1;
  end;
