 reserve X for set;
 reserve S for Subset-Family of X;

theorem
  for X1,X2 be set, S1 be non empty Subset-Family of X1,
  S2 be non empty Subset-Family of X2 holds
  {s where s is Subset of [:X1,X2:]: ex x1,x2 be set st x1 in S1 & x2 in S2 &
  s=[:x1,x2:]} =
  the set of all [:x1,x2:] where x1 is Element of S1, x2 is Element of S2
  proof
    let X1,X2 be set;
    let S1 be non empty Subset-Family of X1;
    let S2 be non empty Subset-Family of X2;
A1: for x be object st x in {s where s is Subset of [:X1,X2:]: ex
    x1,x2 be set st x1 in S1 & x2 in S2 & s=[:x1,x2:]} holds x in
    the set of all [:x1,x2:] where x1 is Element of S1, x2 is Element of S2
    proof
      let x be object;
      assume x in {s where s is Subset of [:X1,X2:]: ex
      x1,x2 be set st x1 in S1 & x2 in S2 & s=[:x1,x2:]};
      then ex s be Subset of [:X1,X2:] st
      x=s & ex x1,x2 be set st x1 in S1 & x2 in S2 & s=[:x1,x2:];
      hence thesis;
    end;
    for x be object st x in the set of all [:x1,x2:] where x1 is Element of S1,
    x2 is Element of S2 holds
    x in {s where s is Subset of [:X1,X2:]: ex x1,x2 be set st
    x1 in S1 & x2 in S2 & s=[:x1,x2:]}
    proof
      let x be object;
      assume x in the set of all [:x1,x2:] where x1 is Element of S1,
      x2 is Element of S2;
      then ex x1 be Element of S1, x2 be Element of S2 st x=[:x1,x2:];
      hence thesis;
    end;
    hence thesis by A1,TARSKI:2;
  end;
