reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;

theorem Th2:
  for L st 0<L & L<1 holds for k holds L to_power k <= 1 & 0 < L to_power k
proof
  let L;
  assume that
A1: 0<L and
A2: L<1;
  defpred X[Nat] means L to_power $1 <= 1 & 0 < L to_power $1;
A3: for k st X[k] holds X[k+1]
  proof
    let k be Nat such that
A4: L to_power k <= 1 and
A5: 0 < L to_power k;
A6: L to_power (k+1) = L to_power k*L to_power 1 by A1,POWER:27
      .= L to_power k*L by POWER:25;
    L to_power k*L<=L to_power k by A2,A5,XREAL_1:153;
    hence thesis by A1,A4,A5,A6,XREAL_1:129,XXREAL_0:2;
  end;
A7: X[0] by POWER:24;
  thus for k holds X[k] from NAT_1:sch 2(A7,A3);
end;
