reserve a,b,c for set;

theorem Th2: :: (B2)
  for X being set, B being Subset-Family of X st B is
  point-filtered covering for T being TopStruct st the carrier of T = X & the
  topology of T = UniCl B holds T is TopSpace & B is Basis of T
proof
  let X be set;
  let B be Subset-Family of X such that
A1: B is point-filtered covering;
  let T be TopStruct such that
A2: the carrier of T = X and
A3: the topology of T = UniCl B;
  T is TopSpace-like
  proof
    union B in UniCl B by CANTOR_1:def 1;
    hence the carrier of T in the topology of T by A1,A2,A3,ABIAN:4;
    hereby
      let a be Subset-Family of T;
      assume a c= the topology of T;
      then union a in UniCl the topology of T by CANTOR_1:def 1;
      hence union a in the topology of T by A2,A3,YELLOW_9:15;
    end;
    let a,b be Subset of T;
    set Bc = {c where c is Subset of T: c in B & c c= a/\b};
    Bc c= bool X
    proof
      let x be object;
      assume x in Bc;
      then ex c being Subset of T st x = c & c in B & c c= a/\b;
      hence thesis;
    end;
    then reconsider Bc as Subset-Family of T by A2;
    assume a in the topology of T;
    then consider Ba being Subset-Family of T such that
A4: Ba c= B and
A5: a = union Ba by A2,A3,CANTOR_1:def 1;
    assume b in the topology of T;
    then consider Bb being Subset-Family of T such that
A6: Bb c= B and
A7: b = union Bb by A2,A3,CANTOR_1:def 1;
A8: union Bc = a /\ b
    proof
      Bc c= bool (a/\b)
      proof
        let x be object;
        assume x in Bc;
        then ex c being Subset of T st x = c & c in B & c c= a/\b;
        hence thesis;
      end;
      then union Bc c= union bool (a/\b) by ZFMISC_1:77;
      hence union Bc c= a /\ b by ZFMISC_1:81;
      let x be object;
      assume
A9:   x in a/\b;
      then x in a by XBOOLE_0:def 4;
      then consider U1 being set such that
A10:  x in U1 and
A11:  U1 in Ba by A5,TARSKI:def 4;
      x in b by A9,XBOOLE_0:def 4;
      then consider U2 being set such that
A12:  x in U2 and
A13:  U2 in Bb by A7,TARSKI:def 4;
A14:  U2 c= b by A7,A13,ZFMISC_1:74;
      x in U1/\U2 by A10,A12,XBOOLE_0:def 4;
      then consider U being Subset of X such that
A15:  U in B and
A16:  x in U and
A17:  U c= U1 /\ U2 by A4,A11,A6,A13,A1;
      U1 c= a by A5,A11,ZFMISC_1:74;
      then U1/\U2 c= a/\b by A14,XBOOLE_1:27;
      then U c= a/\b by A17;
      then U in Bc by A2,A15;
      hence thesis by A16,TARSKI:def 4;
    end;
    Bc c= B
    proof
      let x be object;
      assume x in Bc;
      then ex c being Subset of T st x = c & c in B & c c= a/\b;
      hence thesis;
    end;
    hence thesis by A8,A2,A3,CANTOR_1:def 1;
  end;
  hence T is TopSpace;
  reconsider B9 = B as Subset-Family of T by A2;
  B9 c= the topology of T by A3,CANTOR_1:1;
  hence thesis by A2,A3,CANTOR_1:def 2,TOPS_2:64;
end;
