reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th2:
  seq is non-zero iff for x st x in NAT holds seq.x<>0.TOP-REAL N
proof
  thus seq is non-zero implies for x st x in NAT holds seq.x<>0.TOP-REAL N
  proof
    assume seq is non-zero;
    then
A1: rng seq c= NonZero TOP-REAL N;
    let x;
    assume x in NAT;
    then x in dom seq by Th1;
    then seq.x in rng seq by FUNCT_1:def 3;
    then not seq.x in {0.TOP-REAL N} by A1,XBOOLE_0:def 5;
    hence thesis by TARSKI:def 1;
  end;
  assume
A2: for x st x in NAT holds seq.x<>0.TOP-REAL N;
  now
    let y be object;
    assume y in rng seq;
    then consider x being object such that
A3: x in dom seq and
A4: seq.x=y by FUNCT_1:def 3;
A5: x in NAT by A3,NORMSP_1:12;
    then y<>0.TOP-REAL N by A2,A4;
    then
A6: not y in {0.TOP-REAL N} by TARSKI:def 1;
    y is Point of TOP-REAL N by A4,A5,NORMSP_1:12;
    hence y in NonZero TOP-REAL N by A6,XBOOLE_0:def 5;
  end;
  then rng seq c= NonZero TOP-REAL N by TARSKI:def 3;
  hence thesis;
end;
